Adding additional criteria to Process Builder formula

Question

We have a bypass process when certain emails are sent. I would like to add conditions to the process and I can't seem to get it in a syntax the PB likes.

    AND
($CustomMetadata.Process_Builder_Bypass__mdt.Email_Auto_Update_Provided_To_Customer.Bypassed__c, CONTAINS 
($CustomMetadata.Process_Builder_Bypass__mdt.Email_Auto_Update_Provided_To_Customer.Profiles__c,$Profile.Name))

These are the two conditions I'd like to add to these criteria

([EmailMessage].Parent.Status CONTAINS "TR/CR",
[EmailMessage].Subject CONTAINS "_TR_CR_")

I've tried adding it within the other condition and it says Syntax error "Missing ')'

AND ($CustomMetadata.Process_Builder_Bypass__mdt.Email_Auto_Update_Provided_To_Customer.Bypassed__c, CONTAINS ($CustomMetadata.Process_Builder_Bypass__mdt.Email_Auto_Update_Provided_To_Customer.Profiles__c,$Profile.Name), 
([EmailMessage].Parent.Status CONTAINS "TR/CR",
[EmailMessage].Subject CONTAINS "_TR_CR_"))

When I add this I get "Extra Email Message.Parent.Status", but I added it in the formula builder so I know the syntax is correct.

AND ($CustomMetadata.Process_Builder_Bypass__mdt.Email_Auto_Update_Provided_To_Customer.Bypassed__c, CONTAINS ($CustomMetadata.Process_Builder_Bypass__mdt.Email_Auto_Update_Provided_To_Customer.Profiles__c,$Profile.Name)) 
[EmailMessage].Parent.Status CONTAINS "TR/CR",
[EmailMessage].Subject CONTAINS "_TR_CR_"

Any pointers to documentation or clues as to how to add this would be appreciated.

Answer 1

There's some good resources:

• Formula Operators and Functions
• Use Formula Fields && Advanced Formulas trailheads
• The Build Formula insert actions within the Process Builder (see below). By searching through the functions and clicking insert, you'll see the format for functions.

There's three things within your example that is off:

1. Parenthesis - if you want all conditions met, make sure they're all within the AND function

AND (
    ..everything here...
)

2. Email Status is a picklist field and CONTAINS works on text. You'll need to convert the field value into text using TEXT().
3. Your original formula used CONTAINS correctly (but your additions did not) and the same format/syntax applies even if using a field instead of a custom metadata value.

CONTAINS should be in the format of CONTAINS(text, compare_text) . If that text is a field, then it's just CONTAINS(fieldName, compare_text).

AND(
$CustomMetadata.Process_Builder_Bypass__mdt.Email_Auto_Update_Provided_To_Customer.Bypassed__c,
CONTAINS($CustomMetadata.Process_Builder_Bypass__mdt.Email_Auto_Update_Provided_To_Customer.Profiles__c, $Profile.Name),
CONTAINS(TEXT([EmailMessage].Parent.Status), "TR/CR"),
CONTAINS([EmailMessage].Subject, "_TR_CR_")
)