Text Field data in lookup field

Question

I have a text Field called Called Five9 Inbound Campaign Name and Lookup field called Lead Source Name When I enter any text in Five9 Inbound Campaign Name lets say "Zillow - Affinito" I want to show same data on Lead Source name, which is a lookup field and has "Zillow - Affinito" in its lookup ! Tried process builder but that cannot match text field with lookup

Answer 1

First create a trigger on Lead

    trigger LeadTrigger on Lead (before insert, before update, before delete, after insert, after update, after delete) {

    LeadTriggerHandler handler = new LeadTriggerHandler();   

    if(Trigger.isInsert && Trigger.isBefore){
        handler.BeforeInsert(Trigger.new);
    }
    if(Trigger.isInsert && Trigger.isAfter){
        handler.AfterInsert(Trigger.new, Trigger.newMap);
    }
    if(Trigger.isUpdate && Trigger.isBefore){
        handler.BeforeUpdate(Trigger.new, Trigger.newMap, Trigger.old, Trigger.oldMap); 
    }     
    if(Trigger.isUpdate && Trigger.isAfter){
        handler.AfterUpdate(Trigger.new, Trigger.newMap, Trigger.old, Trigger.oldMap); 
    }
    if(Trigger.isDelete && Trigger.isBefore){
        handler.BeforeDelete(Trigger.old, Trigger.oldMap);
    }
    if(Trigger.isDelete && Trigger.isAfter){
        handler.AfterDelete(Trigger.old, Trigger.oldMap);
    }
}

Next you will want to define an action which executes before insert and before update. Note here that I assume your Lead_Source_Name__c lookup is to campaign.

public class LeadTriggerHandler {

    public void BeforeInsert(List<Lead> newList){
        List<Lead> leadsWithFive9InboundCampaign = new List<Lead>();
        for(Lead l : newList){
            if(l.Five9_Inbound_Campaign_Name__c != null){
                leadsWithFive9InboundCampaign.add(l);
            }
        }
        if(!leadsWithFive9InboundCampaign .isEmpty()){
            populateLeadSourceNameLookup(leadsWithFive9InboundCampaign );
        }
    }

    public void BeforeUpdate(List<Lead> newList, Map<ID,Lead> newMap, List<Lead> oldList, Map<ID,Lead> oldMap){
        List<Lead> leadsWithChangedFive9InboundCampaign = new List<Lead>();
        for(Lead l : newList){
            if(l.Five9_Inbound_Campaign_Name__c != oldMap.get(l.id).Five9_Inbound_Campaign_Name__c ){
                leadsWithChangedFive9InboundCampaign (l);
            }
        }
        if(!leadsWithChangedFive9InboundCampaign .isEmpty()){
            populateLeadSourceNameLookup(leadsWithChangedFive9InboundCampaign );
        }
    }

    private void populateLeadSourceNameLookup(List<Lead> myLeads){
        Set<String> five9CampaignNames = new Set<String>();
        for(Lead l : myLeads){
            if(l.Five9_Inbound_Campaign_Name__c == null){
                l.Lead_Source_Name__c = null;
            } else {
                five9CampaignNames.add(l.Five9_Inbound_Campaign_Name__c);
            }
        }
        Map<String,Id> campaignNameToId = new Map<String,Id>();
        for( Campaign c : [SELECT ID, Name FROM Campaign WHERE Name IN :five9CampaignNames ]){
            campaignNameToId.put(c.name,c.id);
        }
        for(Lead l : myLeads){
            if(l.Five9_Inbound_Campaign_Name__c != null){
                l.Lead_Source_Name__c = campaignNameToId.get(l.Five9_Inbound_Campaign_Name__c));
            }
        }

    }
}

This allows you to populate the lookup without making extraneous update calls like PB would. Let me know if you have any questions!