validation error even when i dont update the record

Question

The Validation Rule doesn’t seem to be working. The Requirement is after the Opportunity Stage is changed to ‘Final Bid Submitted’, the user should be able to only change ‘Opportunity Stage’ field and no other field. Right now, I am being shown the error even if I don’t change anything and click ‘Save’ where Opportunity Stage is ‘Final Bid Submitted’. Please check.

IF(
    (NOT(ISNEW()) && RecordType.Name == 'BAC Overview' && ISPICKVAL(StageName, 'Final Bid Submitted')),
    IF(ISCHANGED(StageName),
        FALSE,
        TRUE
    ),
    FALSE
)

Answer 1

You won't be able to restrict this using Validation rule.To solve your problem, you have two options:

Option 1: Use a trigger to solve this issue.Below is the link you can refer to:

https://developer.salesforce.com/forums/?id=906F00000008xFXIAY

Option 2: You can create a new record type and page layout specific to this Opportunity Stage change (when Stage is updated to Final Bid Submitted, you can change the record type using workflow) and make all other fields read only on this page layout except the Stage Field.

Answer 2

You could rewrite what you have as:

AND(
    NOT(ISNEW()),
    RecordType.Name == 'BAC Overview',
    ISPICKVAL(StageName, 'Final Bid Submitted'),
    NOT(ISCHANGED(StageName))
)

To properly lock, I think what you really want is:

AND(
    RecordType.Name = 'BAC Overview',
    ISPICKVAL(PRIORVALUE(StageName), 'Final Bid Submitted'),
    NOT(ISCHANGED(StageName))
)

You want to check if the StageName value was your locked stage. Since you need PRIORVALUE, the ISNEW check is not necessary.

---

In order to allow empty saves, you would have to check for changes to every field you want to lock. Something like:

AND(
    // existing clauses
    OR(
        ISCHANGED(Field1__c), ISCHANGED(Field2__c) // etc
    )
)

Not very scalable, and you will quickly exceed compile size. One workaround you might be able to use is to populate a Has_Locked_Field_Changed__c checkbox via a before trigger. Then you can loop through a Field Set and see if any locked fields changed in a more scalable manner. This could be a huge performance hit, though, so make sure you only run this logic if the StageName is already the locked value.