Unable to insert and update for trigger.oldmap and Trigger.newmap in apex trigger

Question

1. I have an object called log__c in that fields have Description__c, Action__c(label name :Title)
2. Lookup with Contact object, when I change the phone field of contact the object then in log__c object with Description__c field should be inserted that old phone is 123 and new phone 456 like this my requirement.

I have tried this code but is updating multiple times with check and the Description field is empty, In Description, I need to show old and new values which changed respectively.

trigger oldvalue on Contact (after insert,after update) {   
    Set<Id> lstLogId = new Set<Id>();
    String OlpPhone;
    String NewPhone;
    list<Log__c> logtimeUpdate = new list<Log__c>();
    if(trigger.IsAfter && (trigger.IsUpdate || trigger.IsInsert)){
        for(Contact Con : trigger.new ){
            if(con.Phone != Trigger.oldMap.get(con.Id).Phone){
                OlpPhone = Trigger.oldMap.get(con.Id).Phone;
                NewPhone = con.Phone;
                lstLogId.Add(Con.Id); 
            }
        }
    }
    list<Log__c> logtime =   [Select id,Name,Contact ,Description__c,Action__c FROM Log__c Where Contact In:lstLogId ];
    For(Log__c l : logtime){
        l.Action__c ='check';       
        l.Description__c ='\n phone number old value ='+OlpPhone+  '   New Phone = ' + NewPhone;
        logtimeUpdate.Add(l);
       
    }
    update logtimeUpdate;
}

Error

Answer 1

You should probably use Field History Tracking for this, but in the meantime, here's a corrected version of your code:

trigger oldvalue on Contact (after insert, after update) {   
    Set<Id> contactsWithUpdate = new Set<Id>();
    list<Log__c> logtimeUpdate = new list<Log__c>();

    if (Trigger.isAfter && (Trigger.isUpdate || Trigger.isInsert)) {
        for (Contact contact : Trigger.new) {
            if ((Trigger.isInsert && contact.Phone != null) ||
                (contact.Phone != Trigger.oldMap.get(contact.Id).Phone)) {
                contactsWithUpdate.Add(contact.Id); 
            }
        }
    }

    for (Log__c log :
            [SELECT Contact__c, Description__c, Action__c
                FROM Log__c
                WHERE Contact__c IN :contactsWithUpdate]) {
        String oldPhone = Trigger.isInsert ? '' : Trigger.oldMap.get(log.Contact__c).Phone;
        String newPhone = Trigger.newMap.get(log.Contact__c).Phone;

        log.Action__c = 'check';       
        log.Description__c += '\n phone number old value =' + oldPhone + ', New Phone = ' + newPhone;
        logtimeUpdate.Add(log);       
    }

    update logtimeUpdate;
}

(Since you included a carriage return in the description, I've guessed you want to simply append the new text to an existing description.)

This also has a further problem: this doesn't cater for creating the Contact-specific Log__c records in the first place. That could be addressed here too, but I've not done so since I don't know if you have something else handling this.