Collect text fields in Aggregate Result Query

Question

I have an aggregate result to process OpportunityLineItems by custom field PackageId - using min, max, avg etc for most fields works fine.

However, for a text field I want to collect all the values into one string, probably csv, and then push into my output object.

Is this possible? thanks

I am trying to collect product_subtype__c from OpportunityLineItems that share a packageid__c field - my try to create a map:

Map<string,string> SubTypeMap = new map<string,string>();
List <opportunityLineItem> Records = [select PackageAdId__c, product_subtype__c
       from OpportunityLineItem
      where Opportunityid =: opp.id];

        for(opportunityLineItem record:records){
          SubtypeMap.put(record.PackageAdId__c,
          getValuesFromRecords(record.records, opportunityLineItem.Product_SubType__c));                      
                                        }

Produces this error:

Variable does not exist: records

Answer 1

To get all of the values together by type, you will want to create a map. Here's how you might do that:

Map<String, Set<String>> subTypeValues = new Map<String, Set<String>>();
for(OpportunityLineItem record: records) {
  Set<String> subTypeSet = subTypeValues.get(record.PackageAdId__c);
  if(subTypeSet == null) {
    subTypeValues.put(record.PackageAdId__c, subTypeSet = new Set<String>());
  }
  subTypeSet.add(record.Product_SubType__c);
}

At this point, you've got a Set of values, so to convert them to a comma-separated list, you'd then go about converting them:

Map<String, String> subTypeStrings = new Map<String, String>();
for(String keyValue: subTypeValues.keySet()) {
  subTypeStrings.put(keyValue, String.join(new List<String>(subtypeValues.get(keyValue)),','));
}

After this step, your final map will contain values like:

'KeyA' => '001,002',
'KeyB' => '003',
'KeyC' => '002,004,005'