Modify collection during iteration

Question

I have below code where I need to modify the List during iteration. It throws error. can someone suggest a way out in this case? **Error **

System.FinalException: Cannot modify a collection while it is being iterated.

Apex Code

for(Survey_Question_vod__c  sq: surveyInstanceList )
{
    if(sq.text_vod__c!=null)
    {
        String formattedStr =sq.text_vod__c;
        String[] strArr = formattedStr.split(' ');
        strNumber = strArr[1];
        mynumber=Integer.valueof(strNumber.substring(0,1));
        If(mynumber==count)
        {
            surveyInstanceListsorted.add(sq);
            count++;
        }
        else
        {
            surveyInstanceList.add(sq);
        }
    }
} 

Answer 1

The error that you get is pretty self-explanatory: Cannot modify a collection while it is being iterated.

What you should do instead, is create a new list and fill it instead. For example:

List<Survey_Question_vod__c> tempList = new List<Survey_Question_vod__c>();
for (Survey_Question_vod__c sq :surveyInstanceList) {
    // Your code, but replace surveyInstanceList.add(sq); with:
    tempList.add(sq);
}

EDIT

If you want to sort this list based on some criteria, you should actually write a wrapper class that implements Comparable interface. After that you can simply sort this list with a one-liner:

surveyInstanceList.sort();

For more info check this page

Answer 2

If you really want to use in-place sorting, you might do this:

for(Integer index = 0; index < surveyInstanceList.size(); index++) {
    Survey_Question_vod__c  sq = surveyInstanceList[index];
    if(sq.text_vod__c!=null) {
        If(Integer.valueof(sq.text_vod__c.split(' ')[1].left(1)) == count) {
            surveyInstanceListsorted.add(sq);
            count++;
        } else {
            // -- will step back one to process record that just moved in
            surveyInstanceList.add(surveyInstanceList.remove(index--));
        }
    }
} 

As long as you don't try to modify a collection that's currently being iterated, you're okay. This example works around that by using indices. Also note that we remove the current record as we add it to the end, so that our list won't keep growing in size as we continue.

Answer 3

No you cannot do the modification to the collection item currently being iterated. To do modification(addition/deletion of elements) use another collection element inside the iteration.

List<Survey_Question_vod__c> surveyInstanceListUpdate = new List<Survey_Question_vod__c>();
for(Survey_Question_vod__c  sq: surveyInstanceList )
{
    if(sq.text_vod__c!=null)
    {
        String formattedStr =sq.text_vod__c;
        String[] strArr = formattedStr.split(' ');
        strNumber = strArr[1];
        mynumber=Integer.valueof(strNumber.substring(0,1));
        If(mynumber==count)
        {
            surveyInstanceListsorted.add(sq);
            count++;
        }
        else
        {
            //surveyInstanceList.add(sq); // use another list of Survey_Question_vod__c instead of list being iterated
            surveyInstanceListUpdate.add(sq);
        }
    }
}

Hope it helps.