Can I remove element from a list being looped through

Question

In apex, how can I remove an element from a list being looped?

List<String> companyinfos=new List<String>();
companyinfos.add('a1');
companyinfos.add('a2');
companyinfos.add('a3');
companyinfos.add('b1');
companyinfos.add('b2');

integer index=0;
For(String s: companyinfos)
{
    if(s.contains('a')){
        companyinfos.remove(index);
        index--;
    }
index++;
}  


System.debug(companyinfos);  

ERROR: Cannot modify a collection while it is being iterated.

Answer 1

As long as you don't use the shorthand iteration technique for(Object a : Objects) and use a traditional for loop, it works fine (you must traverse the list in reverse order as the example shows)

Try this:

for (Integer i = (companyinfos.size()-1) ; i>= 0 ; i--){
    String s = companyInfos[i];
    if(s.contains('a')){
        companyinfos.remove(i);
    }
} 

Answer 2

Salesforce prohitbits (or at least used to do that earlier) removing items from list while traversing it.

So, the solution would be to create another list, store all desired elements in there. For e.g.

List<CompanyInfo> companyinfos=new List<companyinfos>();
List<CompanyInfo> finalList=new List<companyinfos>();
companyinfos.add(***);
....

integer index=0;
For(CompanyInfo info: companyinfos)
{

    if(info.item!=****)
    {
        finalList.add(info);
    }
}  
companyinfos = finalList;

Answer 3

Using While loop to remove an element from a list while being looped

If you want to remove an element in a list by checking for a specific condition, you can use while loop instead of for loop. By doing so, you could remove element from list using index.

Here is the sample code to do so

Integer i = 0;
while (i < companyinfos.size()){
    if(companyinfos.get(i).contains('a')){
        companyinfos.remove(i);
    } else {
        i++;
    }
}

Answer 4

First You should find the index of that letter from companyinfos list the remove that index Try this and let me Know

for (Integer i = (companyinfos.size()-1) ; i>= 0 ; i--)
{
    if(companyinfos.contains('a')){
    Integer index =companyinfos.indexOf('a');
    companyinfos.remove(index);
    }
} 

Answer 5

you dont have to remove using indexes. Just add needed the elements into another list.

List<String> companyinfos = new List<String>();
List<String> newCompanyinfos = new List<String>();

companyinfos.add('a1');
companyinfos.add('a2');
companyinfos.add('a3');
companyinfos.add('b1');
companyinfos.add('b2');

for(String s:companyinfos){
    if(!s.contains('a')){
        newCompanyinfos.add(s); // you will get new list without As
    }
}

Answer 6

It is not possible to use delete/remove operation using short-hand iteration so there are many other ways by which you could achieve this.

So here is a forward approach that is when you delete any element then the list get shortened so for this you don't need to increment the index.

Using for loop:

List<String> companyInfos = new List<String>{'a1', 'a2', 'a3', 'b1', 'b2'};

for(Integer index = 0; index < companyInfos.size();)
    if(companyInfos[index].contains('a'))
         companyInfos.remove(index);
    else
        index++;

System.debug(companyInfos);

And you can also use using While loop:

List<String> companyInfos = new List<String>{'a1', 'a2', 'a3', 'b1', 'b2'};

Integer index = 0;
while(index < companyInfos.size())
    if(companyInfos[index].contains('a'))
        companyInfos.remove(index);
    else
        index++;

System.debug(companyInfos);

Answer 7

In Java it's agood practice to use the iterator when removing something from a list being looped:

List<String> companyinfos=new List<String>();
companyinfos.add('a1');
companyinfos.add('a2');
companyinfos.add('a3');
companyinfos.add('b1');
companyinfos.add('b2');

Iterator<String> it = companyinfos.iterator();

while(it.hasNext()){

String next = it.next();

if(next.contains('a')){
  it.remove();
}

}