Attach case to lead by using supplied email trigger not working

Question

trigger Attachtolead on Case (before insert) {
    list<lead> l =new list<lead>();
    list<case> clist =new list<case>();
    set<string> emailtext=new set<string>();
    list<case> cli=new list<case>();
    set<string> lid=new set<string>();
    for (case c : Trigger.new) {
        if(c.ContactID == null && c.Origin=='web')
            emailtext.add(c.SuppliedEmail);
        cli.add(c);
    }
    l=[select id,email,phone,country,fax from lead where email IN: emailtext];
    for(lead l1: l){
        lid.add(l1.id);
    }
    if(lid.size()>0){
        lead l2=[select id,email,phone,country,fax from lead where id IN:lid Limit 1];
        for (case c : cli) {
            c.Lead__c=l2.id; 
        } 
    }     
}

I want to connect case to lead checking with supplied email .but it is not working .can some one can help me regarding this ?

Answer 1

You should be using the Aggregate Query Update pattern, which would look like this:

trigger AssociateToLead on Case (before insert) {
    // Aggregate
    Map<String, Id> leadsByEmail = new Map<String, Id>();
    Case[] filtered = new Case[0];
    for(Case record: Trigger.new) {
         if(record.SuppliedEmail != null && record.ContactId == null && record.Origin == 'Web') {
              leadsByEmail.put(record.SuppliedEmail, null);
              filtered.add(record);
         }
    }
    // Query
    if(leadsByEmail.isEmpty()) {
        return;
    }
    for(Lead record: [SELECT Email FROM Lead WHERE Email IN :leadsByEmail.keySet() AND IsConverted = FALSE]) {
        leadsByEmail.put(record.Email, record.Id);
    }
    // Update
    for(Case record: filtered) {
        record.Lead__c = leadsByEmail.get(record.Email);
    }
}

As for why your code isn't working-- I couldn't even begin to guess. I do know that you'd eventually have problems with your code when you tried to load records manually, but your trigger should at least have worked assuming the SuppliedEmail matched at least one lead.