Loading Attachment With Parent Type Using SOQL

Question

I am trying to load Attachment info along with Type and Id of its parent. I have used the following query before and it worked fine:

SELECT Id, Name, Parent.Id, Parent.Type FROM Attachment

But now for one of the Salesforce instances Parent attribute in response stays null for most of the attachments. I also tried doing something like this:

SELECT Id, Name, Parent.Id, Parent.Type FROM Attachment WHERE Parent.Type = 'Task'

And while filtering works correctly, information about parent is not returned. I am not sure what has changed and why this type of query doesn't work any more.

Any pointers what I should be looking at? Thanks!

---

Update: 22 May 2014

This is not an answer, but as a workaround in my particular case (just need to know Type of the Parent) it is possible to use ParentId value to figure out the Parent Type by getting list of all available SObjects (http://www.salesforce.com/us/developer/docs/api_rest/Content/dome_describeGlobal.htm) and finding the one with correct keyPrefix.

Answer 1

In my experience, Type is NOT returnable as a field in a SOQL query on a polymorphic field (meaning you can't request it in a SELECT clause), but it IS filterable, meaning that you can use it in the WHERE clause. There seems to be a special provision for being able to filter by the SObject Type of a polymorphic field's target object via <PolymorphicField>.Type, but you won't get <PolymorphicField>.Type returned back to you on the rows retrieved.

In general, the reference for which fields are returnable / filterable across a polymorphic field is determined by the set of fields documented in the Name object --- for most objects, the only useful field available is Name, and sometimes FirstName and LastName (on Contact, Lead, and User), and then, when querying a polymorphic field for which one of the possible targets is User, you can get at a bunch of User fields (e.g. queries on Owner.IsActive, Owner.ProfileId will work)

However, you should be able to quickly determine the SObject Type of the Parent object via various workarounds. Since you can query on ParentId, you can check the key prefix of every record and go from there.

For example, from Apex you could do:

// Get a map of our returned Attachments 
// by their parent Object type
Map<Schema.SObjectType,List<SObject>> recordsByObjectType
    = new Map<Schema.SObjectType,List<SObject>>();

for (List<Attachment> atts : [SELECT Id, Name, ParentId FROM Attachment]) {
    for (Attachment a : atts) {
        Schema.SObjectType t = Id.valueOf(a.ParentId).getSObjectType();
        if (!recordsByObjectType.containsKey(t)) {
            recordsByObjectType.put(t,new List<SObject>());
        }
        recordsByObjectType.get(t).add(a);
    }
}

// Grab all Attachments to Account records
List<SObject> accountAttachments = recordsByObjectType.get(Account.SObjectType);
// Grab all Attachments to Task records
List<SObject> taskAttachments = recordsByObjectType.get(Task.SObjectType);