Dynamically get a namespace prefix

Question

In an app that I'm creating, there are some places where I need to create objects based on their string name, and need to take the apps namespace prefix into account dynamically.

I've created this function that will grab the ns based on one of the custom object names:

public static String getNamespacePrefix() {
    String namespace = '';
    try {
        ApexClass ac = [SELECT NameSpacePrefix FROM ApexClass WHERE Name = 'CUSTOM_CLASS_NAME'];
        if(null != ac.NameSpacePrefix) {
            namespace = ac.NameSpacePrefix + '__';
        }
    } catch (QueryException ex) {
        // do nothing
    }
    return namespace;
}

There are a handful of places that call this function which is causing me to run into SQL query limits.

Is there a better way to do this? Or a way to make the namespace somehow globally available one time?

Answer 1

public with sharing class MynamespaceClass{

   public static final String CURRENTNAMESPACE = MynamespaceClass.class.getName().substringBefore('MynamespaceClass').removeEnd('.');
 }

The above is simplest way to get namespace

Answer 2

Yes, you can get it from a custom object (that has the namespace prefix, of course).

public static String getNamespace_Underline()
{
    DescribeSObjectResult describe = YourCustomObject__c.SObjectType.getDescribe();

    String name = describe.getName();
    String localName = describe.getLocalName();

    return name.removeEnd(localName);
}

This would return your prefix with a dot at the end ("myprefix.").

Answer 3

I found a solution on this page and ended up going with the following:

public static String getNamespacePrefix() {
    Integer indexOfToken = -1;
    String namespace = '';
    for ( Schema.SObjectType type : Schema.getGlobalDescribe().values() ) {
        String sobjName = String.valueOf(type);

        if (null != sobjName) {
            indexOfToken = sobjName.indexOf('ObjectName__c');
        }

        if (indexOfToken != -1) {
            namespace = sobjName.substring(0, indexOfToken);
            break;
        }
    }

    return namespace;
}