How to change due date on task for a case from Developer Console

Question

I am trying to change the due date on task from Developer console and here is my code so far:

list<case> sc = [select Id, casenumber, (select Id, ActivityDate from openactivities) FROM case LIMIT 50]; list<task> oa = new list<task>();

for(case c:sc){
    for(task o : c.task){
        system.debug(o.ActivityDate);
    }    
}

But I am getting an error

Invalid field task on case

So how to reference tasks from cases. Can someone help me on this.

Query in the first line is working perfect in workbench to pull records. But when I am using openactivities as child object getting error "Invalid field openactivities on case"

Update: Here is the query I am trying to use after reply by sfdcfox:

SELECT Id, ActivityDate, subject, WhatId FROM Task WHERE WhatId IN (SELECT Id FROM Case) 

Requirement: I have cases with case number from 1 to 100 and I need to pull cases with case numbers from 50 to 75. How to add where clause to pull all tasks with case numbers between 50 and 75.

When I try to add WHERE clause to inner query I get an error

Unknown error parsing query

Thanks

Answer 1

I think it might be something about how you structured your WHERE clause, perhaps? Usually unknown error parsing query is about wrong field name, missing chars etc. I've tried below code and it works just fine.

   Set<String> caseNumbers = new Set<String>();
    for(Integer i = 50; i < 76; i++){
        caseNumbers.add(String.valueOf(i));
    }
    Task[] tasks = [Select Id, ActivityDate, Subject, WhatId FROM Task
                   WHERE WhatId IN (SELECT Id FROM Case WHERE CaseNumber IN :caseNumbers)];

UPDATE: Firs please see updated code below.

for(Task t: tasks){
    t.ActivityDate = Date.newInstance(2015, 7, 23);


}

update tasks;

Instead of parsing date from string, it is a good idea to use newInstance method of Date class. For more info; https://developer.salesforce.com/docs/atlas.en-us.apexcode.meta/apexcode/apex_methods_system_date.htm

Also as you can see update is happening outside of the for loop. You should always check this. Because of Salesforce's limits it is best to not use a SOQL query or a DML statement inside a for loop. (It is also better approach.)

Answer 2

You're looking for "OpenActivites." That's what you queried for. However, I think it'd be a lot easier to just query from the other direction:

Task[] tasks = [SELECT ActivityDate, WhatId FROM Task WHERE What.Type = 'Case' AND IsClosed = FALSE];
for(Task record: tasks) {
    // Do what you will here
}
update tasks;

As for your original code:

for(Case caseRecord: sc) {
    for(Sobject activityRecord: caseRecord.OpenActivities) {
        if(activityRecord.getSObjectType() == Task.SObjectType) {
            Task taskRecord = (Task)activityRecord;
            // Do stuff here
        }
    }
}

"OpenActivites" and "ActivityHistories" are Activity types, not Task types. They contain both tasks and events, so you have to determine which you're looking at before you can use it as a task.

You should also be able to use a sub-query on the new code I suggested:

SELECT Id, ActivityDate, WhatId FROM Task WHERE WhatId IN (SELECT Id FROM Case WHERE ...) AND IsClosed = FALSE

Answer 3

Thanks Tugce for your reply.. seems like it is working.. but can you please correct me on this.. I am not getting any error but the due date is not changing after running this script.. Can you please look in to this..

    Set<String> caseNumbers = new Set<String>();
        for(Integer i = 129162; i < 129163; i++){
            caseNumbers.add(String.valueOf(i));
        }
    Task[] tasks = [Select Id, ActivityDate, Subject, WhatId 
                    FROM Task
                    WHERE WhatId IN 
                        (SELECT Id FROM Case 
                         WHERE CaseNumber IN :caseNumbers)];
    for(task t: tasks){
        t.activitydate = date.parse('07/23/2015');
update tasks;
    }

Thanks