How to display the complete row from the data extension?

Question

I want to display the complete row from the data extension on the web page.

%%[ 
VAR @Rows,@email
SET @email = QUERYPARAMETER("email") 
SET @data = QUERYPARAMETER("Trigger")
SET @Rows = LOOKUPROWS(@data,"EmailAddress",@email)
]%% 

So I want to display all the columns for the @Rows.

Answer 1

In case the column count is the same for each data extension you could use two iterations one for column and one for rows, or you can change the @colcount according to each data extension.

%%[
set colCount = 5
For @row = 1 to RowCount(@Rows) do
    For @col = 1 to @colCount do
]%%
|%%=Field(Row(@Rows,@row),@col)=%%|
%%[
    next @col
next @row
]%%

Answer 2

You'll need to iterate through the @rows result-set and use the Row() and Field() functions to retrieve the column values.

For example

%%[
var @rows, @row, @rowCount, @numRowsToReturn, @lookupValue, @i

set @lookupValue = "whee"
set @numRowsToReturn = 0 /* 0 means all */
set @rows = LookupOrderedRows("DataExtensionName",@numRowsToReturn,"DEColumn1 desc, DEColumn2 asc","LookupColumn", @lookupValue)
set @rowCount = rowcount(@rows)

if @rowCount > 0 then

for @i = 1 to @rowCount do

var @DEColumn1, @DEColumn2
set @row = row(@rows,@i) /*get row based on loop counter */
set @DEColumn1 = field(@row,"DEColumn1")
set @DEColumn2 = field(@row,"DEColumn2")

]%%

Row %%=v(@i)=%%, DEColumn1 is %%=v(@DEColumn1)=%%, DEColumn2 is %%=v(@DEColumn2)=%%

%%[

next @i ]%%

%%[ else ]%%

No rows found

%%[ endif ]%%