How to update null records in JSON

Question

I'm currently working on the below JSON. Sometimes records in matches return null, instead of record. And null will appear anywhere within the array

{
    "status": "success",

    "error_code": null,

    "matches": [

     {

      "status": "success",

      "error_code": null,

     }
      ,null,

     {}]

}

Apex code:

if(jsonResponse.contains(',null,'))

{

  jsonResponse =  jsonResponse.replaceAll(',null,', ',{"id": ""},');

}

if(jsonResponse.contains('null\\,{'))

{ 

  jsonResponse =  jsonResponse.replaceAll('null\\,{', '{"id": ""},{');

}

if(jsonResponse.contains('null\\]'))

{            

   jsonResponse =  jsonResponse.replaceAll('null\\]', '{"id": ""}]');

}

Please guide me on how to replace null with array #Json #Apex #Trailhead

Answer 1

Try something like this instead of manipulating the string directly:

Map<String, Object> data = (Map<String, Object>) JSON.deserializeUntyped(jsonResponse);

List<Object> matches = (List<Object>) data.get('matches');

for(Integer i = 0; i < matches.size(); i++) {
    if(matches[i] == null) {
        matches[i] = new Map<String, String>{'id' => ''};
    }
}

data.put('matches', matches);
String newJsonResponse = JSON.serialize(data);

Answer 2

Do not manipulate the string. Deserialize it and remove the null from the list.

The first step is define a custom Apex class to map that response, then you can leverage typed deserialization, finally you can loop over the list of matches and remove null objects

ResultWrapper result = (ResultWrapper) JSON.deserialize(jsonResponse, ResultWrapper.class);
if (result.matches != null) {
    for (Integer i = result.matches.size() - 1; i >= 0; i--) {
        // remove both null and empty objects
        if (result.matches[i] == null || String.isBlank(result.matches[i].status)) {
            result.matches.remove(i);
            // here you could add a new object at the same position if you want
        }
    }
}
System.debug(result);

Answer 3

public class Match {
    public String status;
    public String error_code;
}

public class JsonResponse {
    public String status;
    public String error_code;
    public List<Match> matches;
}

public static void replaceNullMatches(String jsonString) {
    JsonResponse response = (JsonResponse) JSON.deserialize(jsonString, JsonResponse.class);
    
    for (Integer i = 0; i < response.matches.size(); i++) {
        if (response.matches[i] == null) {
            Match defaultMatch = new Match();
            defaultMatch.status = 'default_status';
            defaultMatch.error_code = 'default_error';
            response.matches[i] = defaultMatch;
        }
    }

    // If you want to get updated JSON string back:
    String updatedJsonString = JSON.serialize(response);
    System.debug(updatedJsonString);
}

String jsonString = '{ "status": "success", "error_code": null, "matches": [ { "status": "success", "error_code": null }, null, {} ] }';
replaceNullMatches(jsonString);