Is it possible to Generically deserialize a Json string wit nested arrays in Apex

Question

I want to be able to Generically deserialize a Json string with nested arrays for a web-service, since the structure isn't known beforehand and kan change a lot. I did some reading a seems doable but not more than 4 levels deep.

Please point me in the right direction with an example since this seems to be possible for 1 level, how to do this with nested arrays given not more than 4 levels deep.

My current approach would be:

1. An interface to talk to from outside
2. Generically deserialize Json
3. Custom metadata to map field to sObject

Thanks in advance.

Answer 1

The API to deserialize JSON of indeterminate structure is:

JSON.deserializeUntyped

described in the JSON Class documentation. I have used this often and have not hit any depth problems; add a link to any evidence of that.

That will return arrays and maps of Object and so your code will need to cast appropriately. This can be static - the code assumes and casts - or dynamic - the code uses instanceof (and other type detection) and bases the casting on that. Putting the mapping to SObject fields in some kind of configuration or at the very least in some static Apex maps makes sense. Note that you will probably have to implement type conversion for e.g. dates

(Perhaps not relevant here, but in general, do consider json2apex that has the benefit of generating data holding classes for you. If your JSON only has a small number of permutations you could generate per permutation and select the appropriate one via a preliminary JSON.deserializeUntyped.)

My goto reference for what can turn up in JSON is this single Introducing JSON page.

Answer 2

To Deserialize JSON you can use:

JSON.deserializeUntyped

To parse JSON for multiple levels using JSON.deserializeUntyped you need another layer of typecasting.

Here is an example:

JSON To Parse:

{
   "Candidates":[
      {
         "Name":"ABC",
         "Exp":25,
         "Languages":[
            {
               "Name":"Apex",
               "version":[
                  
               ]
            },
            {
               "Name":"Java",
               "versions":[
                  {
                     "version":1.8,
                     "certification":true,
                     "placeholder":
                        {
                           "target":"reached"
                        }
                  }
               ]
            }
         ]
      },
      {
         "Name":"DEF",
         "Exp":26
      }
   ]
}

Let's say we need to reach the target attribute. Levels are Candidates>Languages>versions>placeholder>target.

You can achieve it by additional type casting for each level you move. Here is the solution:

String jsonInput = '{'+
   '"Candidates":['+
      '{'+
         '"Name":"ABC",'+
         '"Exp":25,'+
         '"Languages":['+
            '{'+
               '"Name":"Apex",'+
               '"versions":['+
                  
               ']'+
            '},'+
            '{' +
               '"Name":"java",'+
               '"versions":['+
                  '{'+
                     '"version":1.8,'+
                     '"certification":true,'+
                     '"placeholder":'+
                        '{'+
                           '"target":"reached"'+
                        '}'+
                     ''+
                  '}'+
               ']'+
            '}'+
         ']'+
      '},'+
      '{'+
         '"Name":"DEF",'+
         '"Exp":26'+
      '}'+
   ']'+
'}';

//Deserialize the specified JSON string into collections of primitive data types.
Map<String, Object> m = 
   (Map<String, Object>)
      JSON.deserializeUntyped(jsonInput);
//level-1     
List<Object> Candidates = (List<Object>)m.get('Candidates');

for(Object Candidate : Candidates){
    String Name = (String)((Map<String, Object>) Candidate).get('Name');
    if(Name == 'ABC'){
        //level-2
        List<Object> Languages = (List<Object>)((Map<String, Object>) Candidate).get('Languages');
        for(Object Language : Languages){
            String LanguageName = (String)((Map<String, Object>) Language).get('Name');
            if(LanguageName == 'java'){
                //level-3
                List<Object> versions = (List<Object>)((Map<String, Object>) Language).get('versions');
                for(Object version : versions){
                    Decimal versionNo = (Decimal)((Map<String, Object>) version).get('version');
                    if(versionNo == 1.8){
                        //level-4
                        Map<String, Object> placeholder = (Map<String, Object>)((Map<String, Object>) version).get('placeholder');
                        //level-5
                        String target = (String)placeholder.get('target');
                        System.debug(target);
                    }
                }
            }
        }
    }
}