Cannot convert list of objects to specific type

Question

I've created a method to extract a specific field from a list of sObjects, and since it accepts any sObject, I return a list of Object too, since field types can vary.

So the method is as follows:

public static List<Object> getFieldFromSobjectList(List<SObject> objects, String field_name) {
    List<Object> result = new List<Object>();
    for (SObject obj : objects) {
        try {
            result.add(obj.get(field_name));
        } catch (Exception e) {
            // ... shh bb is ok
        }
    }
    return result;
}

The method returns a list of objects and I'm trying to convert the result to a list of ids, using casting:

List<Id> list_of_ids = (List<Id>) Utils.getFieldFromSobjectList(list_of_objects, 'Id');

Even though this code can be compiled, at runtime it throws me an error:

System.TypeException: Invalid conversion from runtime type List<ANY> to List<Id>

Answer 1

Here is my Utility class that does this with props to @sfdcfox

//  ------------------------------------------------------
//  getIdSetFromField   : gets a set of Ids from a list of sobjects in <field>
//  ------------------------------------------------------
public static Set<ID> getIdSetFromField(SObject[] records, SObjectField fieldname) {
    return new Set<ID> ((List<ID>) getValListFromField(List<ID>.class, records, fieldname));
}

//  --------------------------------------------------------
//  getValListFromField     : Returns a list of field values from a list of sobjects; ref: http://salesforce.stackexchange.com/a/64949/2602
//                          : Usage Ex: Decimal[] amountList = (Decimal[])Util.getValListFromField(Decimal[].class,Trigger.new,Opportunity.Amount);
//  --------------------------------------------------------
public static Object[] getValListFromField(Type resListType, SObject[] records, SObjectField fieldname) {
    Object[] res    = (Object[])resListType.newInstance();
    for (SObject sObj: records)
        res.add(sobj.get(fieldname));
    return res; 
}

Usage

set<ID> ids = Util.getIdSetFromField(Trigger.new,Opportunity.AccountId);

or, if you want a list

ID[] ids = new List<ID>(Util.getIdSetFromField(Trigger.new,Opportunity.AccountId));

Answer 2

It appears to me that you've not typed the sObject to retrieve it's name too which may be causing your issue since you're retrieved the field name. If you did that, you could return the list<sObject Name> which would have the Ids instead of just the field_name.

Answer 3

While get method returns string, you can collect list <string> and in end convert it to list of ids:

list<String> strIds = new list<String>{'001M000000vs9Mh','001M000000vs9Mh'};
list<id> myIds = new list<id>();
myIds.addall((list<id>)strIds);
system.debug(myids);

For Integer you have to convert each value implicitly:

list<String> strIds = new list<String>{'150','123'};
list<integer> myInts = new list<integer>();
for (String id :strIds){
    myInts.add(integer.valueof(id));
}
system.debug(myInts);