Global variable isn't updating on my Apex Trigger

Question

During a merge of leads I'm trying to combine the descriptions from the old leads.

In the Trigger.isDelete section, my variable newLeadDescription variable receives all the old descriptions added together.

But when I try to use the updated newLeadDescription in the Trigger.isUpdate of my code, newLeadDescription still equals ''.

How do I globally update newLeadDescription?

trigger MergeLeadDescriptions on Lead (before delete, before update) {

List<String> leadDescriptions = new List<String> ();

String newLeadDescription = '';


if (Trigger.isDelete) {

    Integer i = 0;

    if (Trigger.isBefore) {
        for(Lead o : Trigger.Old) {
            leadDescriptions.add(o.Description);
            System.debug('The old lead description is ' + leadDescriptions[i]);
            newLeadDescription = newLeadDescription + ' ' + leadDescriptions[i];
            System.debug('Current newLeadDescription value is ' + newLeadDescription);
            i++;
        }
    }
}
else if (Trigger.isUpdate) {

    if (Trigger.isBefore) {
        for(Lead n : Trigger.New) {
            //n.Description = n.Description + ' ' + newLeadDescription;
            System.debug('Current newLeadDescription in this scope is ' + newLeadDescription);
            System.debug('The new lead description is ' + n.Description);


        }
    }
}  
}

Answer 1

You need a static variable in a class in order to do this:

public class StaticData {
    public static Map<Id, String> descriptions = new Map<Id, String>();
}

Then, you can keep your data there:

trigger KeepDescriptions on Lead (after delete, before update) {
    if(Trigger.isAfter) { // After delete
        for(Lead record: Trigger.old) {
            if(record.MasterRecordId != null && record.Description != null) { // Indicates a merge
                // Multiple records might match
                String description = StaticData.descriptions.get(record.MasterRecordId);
                if(description == null) { 
                    description = '';
                }

                description += '\n\n'+record.Description;
                StaticData.descriptions.put(record.MasterRecordId, description);
            }
        }
    }
    if(Trigger.isBefore) { // Before update
        for(Lead record: Trigger.new) {
            if(StaticData.descriptions.containsKey(record.id)) {
                if(record.Description == null) {
                    record.Description = '';
                }
                record.Description += StaticData.descriptions.get(record.Id);
            }
        }
    }
}

You can read more about Triggers and Merge Statements to get a better idea of what this trigger is doing.