Email opt out from converted Lead

Question

I want to update the email optout field from converted contact to the existing contacts. For ex lets say i have 3 contacts with same email address([email protected]) and emailoptout not checked and iam converting new lead with emailoptout box checked and has same email([email protected]), i want my trigger to update the email optout box to true on these 3 existing contacts.

trigger updateLeadOnEmailOptOut on Lead (after update) {
    List<Lead> duplicateLeads = new List<Lead>();
    Map<String, Lead> leadEmailMap = new Map<String, Lead>();
    Map<Id, Lead> leadIdMap = new Map<Id, Lead>();
    Map<Id, Contact> contacts = new Map<Id, Contact>();

    for (Integer i = 0; i < Trigger.new.size(); i++) {
        if (Trigger.old[i].HasOptedOutOfEmail != Trigger.new[i].HasOptedOutOfEmail) {
            leadEmailMap.put(Trigger.old[i].email, Trigger.new[i]);
            leadIdMap.put(Trigger.old[i].id, Trigger.new[i]);        
        }
    }    

    if ( leadIdMap.size() > 0 ) {
        for ( Lead dupLead : [SELECT Id, Name, Email, HasOptedOutOfEmail FROM Lead
                                WHERE Email IN : leadEmailMap.KeySet()
                                AND Id NOT IN : leadIdMap.KeySet()
                                AND IsConverted = FALSE]) {
                                 Lead lead = leadEmailMap.get(dupLead.Email);
            if (dupLead.HasOptedOutOfEmail <> lead.HasOptedOutOfEmail) { 
                dupLead.HasOptedOutOfEmail = lead.HasOptedOutOfEmail;   
                duplicateLeads.add(dupLead);
            }
        }

        if ( duplicateLeads.size() > 0 )
            update duplicateLeads;
    }
    for ( Lead record : Trigger.new ) {
        if ( record.ConvertedContactId != null ) {
            contacts.put(record.ConvertedContactId, new Contact(Id=record.ConvertedContactId, HasOptedOutOfEmail=record.HasOptedOutOfEmail));
        }
    }
    update contacts.values(); 
}

Answer 1

Yes, in your after update lead trigger, you can update the selected contact using something like this:

Map<Id, Contact> contacts = new Map<Id, Contact>();
for(Lead record: Trigger.new) {
    if(record.ConvertedContactId != null) {
        contacts.put(record.ConvertedContactId, new Contact(Id=record.ConvertedContactId, HasOptedOutOfEmail=record.HasOptedOutOfEmail));
    }
}
update contacts.values();

As an aside, "guarding" against an empty list is an obsolete technique.

Answer 2

The solution may be much simpler than you coded (assumes that you really only care about setting emailOptOut to true on existing contacts if Lead indicates they want to optOut. If the lead opts in, then the converted contact will automatically also optIn on lead conversion

trigger syncEmailOptoutWithContactsOnLeadConversion on Lead (after update) {
   Set<String> emailSearchSet = new Set<String> ();
   for (Lead l : Trigger.new)
     if (l.isConverted && l.hasOptedOutofEmail && l.email != null)
        emailSearchSet.add(l.email);

  List<Contact> cUpdList = [select id, hasOptedOutOfEmail 
                             from Contact 
                             where email IN :emailSearchSet and
                                   hasOptedOutOfEmail = false
                           ];
  for (Contact c : cUpdList)
      c.hasOptedOutOfEmail = true;

  try {  // you could do partial success logic here and correlate
         // any database error back to the offending triggered item
         // but this is an exercise left for you
    update cUpdList;
  }
  catch (Exception e) {//do something useful - prevent conversion? send email? you decide}
}