How to switch on RecordTypeId inside a loop?

Question

Alternative Title : How to optimize grouping each SObject records by Recordtypes

public static Id sgRecordTypeId = Schema.SObjectType.Account.getRecordTypeInfosByDeveloperName().get('Singapore').getRecordTypeId();
public static Id myRecordTypeId = Schema.SObjectType.Account.getRecordTypeInfosByDeveloperName().get('Malaysia').getRecordTypeId();

for(Account accObj : newAccountList) {
     SWITCH on accObj.RecordTypeId {
        when sgRecordTypeId {
            sgAccountIdSet.add(accObj.Id);
        }
        when myRecordTypeId {
            myAccountIdSet.add(accObj.Id);
        }
...
}

When I do the above code I get this error : Id is not a valid switch expression type

So I tried changing it to SWITCH on String.valueOf(accObj.RecordTypeId) { as mentioned here but get these errors:

1. null occurs as more than one when branch for this switch statement
2. Field must be an enum reference

Realised the error is because You can only use explicit string literals (no variables)

But got stuck here ...

Note : Don't want to use if/else statement because it will make the Apex PMD complain about the cyclomatic complexity

Answer 1

Switch statements can only work on static (compile-time) values, not any computed value. As such, you might want to work with record type names instead:

Map<Id, RecordType> recordTypes = new Map<Id, RecordType>([
  SELECT Name FROM RecordType WHERE sObjectType = 'Account'
]);
for(Account accRecord: newAccountList) {
  switch on recordTypes.get(accRecord.RecordTypeId)?.Name {
    when 'Singapore' {
      ...
    }
    when 'Malaysia' {
      ...
    }
  }
}

For your specific use case, you can also use a Map by way of references:

public static Id sgRecordTypeId = Schema.SObjectType.Account.getRecordTypeInfosByDeveloperName().get('Singapore').getRecordTypeId();
public static Id myRecordTypeId = Schema.SObjectType.Account.getRecordTypeInfosByDeveloperName().get('Malaysia').getRecordTypeId();
Set<Id> sgAccountIdSet = new Set<Id>();
Set<Id> myAccountIdSet = new Set<Id>();
Map<Id, Set<Id>> accountIdsByRecordTypeId = new Map<Id, Set<Id>> {
  sgRecordTypeId => sgAccountIdSet,
  myRecordTypeId => myAccountIdSet
};
for(Account record: newAccountList) {
  accountIdsByRecordTypeId.get(record.RecordTypeId)?.add(record.Id);
}

Because objects are accessed by reference, updating the value in the Map will update the related set variables.

Answer 2

Per my understanding, you want to group account ids by their RecordTypeId. Consider using a Map for this purpose. It reduces sets where you are storing grouped elements:

Map<Id, Set<Id>> accountsIdsByRecordTypeId = new Map<Id, Set<Id>>();

for(Account accObj : newAccountList){
    Set<Id> accountIds = new Set<Id>();
    if(accountsIdsByRecordTypeId.containsKey(accObj.RecordTypeId)){
        accountIds = accountsIdsByRecordTypeId.get(accObj.RecordTypeId);
    }
    accountIds.add(accObj.Id);
    accountsIdsByRecordTypeId.put(accObj.RecordTypeId, accountIds);
}

Key of accountsIdsByRecordTypeId is a RecordTypeId of Account and value is a Set of Account ids.

---

if you have to group accounts only by specific RecordTypeId, create another Set to store ids to filter:

Map<String, Schema.RecordTypeInfo> recordTypeInfos = Schema.SObjectType.Account.getRecordTypeInfosByDeveloperName();

Set<Id> accountRecortypeIdsToGroupBy = new Set<Id> {
    recordTypeInfos.get('Singapore').getRecordTypeId(),
    recordTypeInfos.get('Malaysia').getRecordTypeId();
};

Map<Id, Set<Id>> accountsIdsByRecordTypeId = new Map<Id, Set<Id>>();

for(Account accObj : newAccountList){
    if(accountRecortypeIdsToGroupBy.contains(accObj.RecordTypeId)) {
        Set<Id> accountIds = new Set<Id>();
        if(accountsIdsByRecordTypeId.containsKey(accObj.RecordTypeId)){
            accountIds = accountsIdsByRecordTypeId.get(accObj.RecordTypeId);
        }
        accountIds.add(accObj.Id);
        accountsIdsByRecordTypeId.put(accObj.RecordTypeId, accountIds);
    }
}