How to query relationship fields before insert?

Question

I need to populate a record with the values of a parent record before insert. These fields mirror some fields from the parent record, but should be editable by the user (so we can't use formulas).

Because this runs before insert, I'm unable to query the relationship fields the standard way (SELECT ParentObject.Name FROM ... ) because the trigger record ids don't exist yet.

This leaves me with some options:

1- Keep track of the related record ids, query them separately, and do the joins manually later in the code. This requires a lot of boilerplate code so I'm not too excited about it.

2- Do this in a @future method, however I need the field values to be populated before any other logic can run

3- Do it after update, by putting a dummy workflow that fires all the time and re-fires the trigger context. Not too excited either because of recursion.

Are there option/better options?

Answer 1

Just use a Map, as I posted in my post years ago, which I call the Aggregate-Query-Update pattern.

Map<Id, Parent> parents = new Map<Id, Parent>();
// Aggregate //
for(Child record: Trigger.new) {
  parents.put(record.ParentId, null);
}
// Query //
parents.putAll([SELECT Field FROM Parent WHERE Id = :parents.keySet());
// Update //
for(Child record: Trigger.new) {
  Parent parent = parents.get(record.ParentId);
  if(parent != null) {
    // Additional handling //
  }
}

Edit: I realize that this is probably what you mean by "option 1"; if you find that you need this a lot, abstract it!

public static Set<Id> getIdsFromRecords(sObject[] records, sObjectField field) {
  Set<Id> values = new Set<Id>();
  for(sObject record: records) {
    values.add((Id)record.get(field));
  }
}

So you can then:

Map<Id, Parent> parents = new Map<Id, Parent>([
  select field from Parent where id = :Utils.getIdsFromRecords(Trigger.new, Child.ParentId)
]);