Sorting of two different records referencing their dates

Question

I just want to ask if comparing of each fields on separate object is possible in order to show first the most recent.

Example, I have Object A and Object B, and Object A has Hired_Date__c , and Object B has Hired_Date__c also,

is it possible to sort them in a way of comparing using comparable.

if(Object A.Hired_Date__c > Object B.Hired_Date__c){
   return 1;
}

else if (Object A.Hired_Date__c < Object B.Hired_Date__c){
   return -1;
}

else {
    return 0;
}

so that I could display on visualforce page the arrangement of Object A1 Object B2, so on . . or how could I achieve to sort this 2 different records?

Answer 1

It is possible to write a Comparable wrapper class that can work with various SObject types and fields:

public class DateFieldComparable implements Comparable {

    private SObject sob;
    private SObjectField field;

    public DateFieldComparable(SObject sob, SObjectField field) {
        this.sob = sob;
        this.field = field;
    }

    public Integer compareTo(Object o) {

        DateFieldComparable that = (DateFieldComparable) o;

        Date thisValue = (Date) this.sob.get(field);
        Date thatValue = (Date) that.sob.get(that.field);

        if (thisValue < thatValue) return -1;
        else if (thisValue > thatValue) return 1;
        else return 0;
    }

    public SObject getSObject() {
        return sob;
    }
}

that can then be used like this:

// Wrap and sort
DateFieldComparable[] fcs = new DateFieldComparable[] {};
for (Project__c p : projects) {
    fcs.add(new DateFieldComparable(p, Project__c.MyDateField__c));
}
for (assignment__c : assignments) {
    fcs.add(new DateFieldComparable(a, Assignment__c.OtherDateField__c));
}
fcs.sort();

// Pull back out the sorted objects
SObject[] sobs = new SObject[] {};
for (FieldComparable fc : fcs) {
    sobs.add(fc.getSObject());
}

This code is using the SObjectField token to represent a field which has the benefit that the compiler checks that the field exists. But if it is more convenient, you can use a string that holds the field API name because there is an SObject.get available for both types.

PS

Changed to a specific data type per sfdcfox's comment.

Answer 2

Yes, that should be no problem: This is exactly what the Comparable interface is for.

global class Object implements Comparable { // Change this "Object" to your object name
    Date hiredDate;

    public Object(Date hd){ // Change this "Object" to your object name
        hiredDate = hd;
    }

    global Integer compareTo(Object compareTo) { // DO NOT change this "Object" to your object name
        Object compareToObject = (Object) compareTo;
        // Change this "Object" to your object name 
        // This line is important, make sure you cast to your custom object

        if(hiredDate == compareToObject.Hired_Date__c) return 0;
        if(hiredDate > compareToObject.Hired_Date__c) return 1;
        return -1;
    }
}

Please refer to the documentation for more examples & explanations: https://developer.salesforce.com/docs/atlas.en-us.apexcode.meta/apexcode/apex_comparable.htm