Calling .put on Map of Custom Settings cause 'Collection is read only' Apex error

Question

I create a map of Custom Settings and then try to add a new one to it. But it throws the error

AssignByLeadSource: execution of BeforeInsert caused by: System.FinalException: Collection is read-only: External entry point

Here is the code. I removed the offending line counters.put(record.LeadSource, happydog); and tested everything else and found no errors, works great.

trigger AssignByLeadSource on Lead (before insert) {
    // Use row locks to prevent race conditions
    {
        LeadSourceCounters__c[] temp = [SELECT Id FROM LeadSourceCounters__c FOR UPDATE];
        //LeadSourceCounters is a custom setting
    }

    Map<String, LeadSourceCounters__c> counters = LeadSourceCounters__c.getAll();
    //counters is a new map that pulls in all the counts from the custom setting.

    System.debug('LeadSourceCounters__c.getAll() = ' + LeadSourceCounters__c.getAll());
    System.debug(counters);

    for(Lead record: Trigger.new) {
        if(record.LeadSource==null) {
            //if LeadSource is null, we can't round robin it specially, so continue ends for loop.
            continue;
        }

        if(!counters.containsKey(record.LeadSource)) {
        //if LeadSource doesn't exist, adds it and sets value to zero.    

            LeadSourceCounters__c happydog = new LeadSourceCounters__c(
                Name=record.LeadSource, 
                Value__c=0
            );

            counters.put(record.LeadSource, happydog);
            //put(name in map, map data is leadsourcecounter data with Name and Value)
        }

        counters.get(record.LeadSource).Value__c+=1;
        //add 1 to Value__c counter for that lead source
        record.AssignmentId__c = counters.get(record.LeadSource).Value__c;
    }
    upsert counters.values();
    //saves the updated counter for that lead source
}

I was under the impression that maps were mutable, and I could add items to them? Are there exceptions to this? How can I add a new Custom Setting to the map?

Answer 1

I suggest you first try using this map constructor to make a mutable copy of the map:

Map<String, LeadSourceCounters__c> counters
        = new Map<String, LeadSourceCounters__c>(LeadSourceCounters__c.getAll());

and leave the rest of your code as is.

Answer 2

I would try to do this for the map (I haven't tested but it should work):

List<LeadSourceCounters__c> listCounters = [select Name, Value__c from LeadSourceCounters__c];

Map<String, LeadSourceCounters__c> counters = new Map<String, LeadSourceCounters__c>();

for (LeadSourceCounters__c cnt : listCounters) {
  counters.put(cnt.Name, cnt);
}

I know it's more work, but that list won't be read only.

Answer 3

Apparently a map that results from a query is immutable. So by calling clone you get a mutable map.

Map<String, LeadSourceCounters__c> counters = LeadSourceCounters__c.getAll().clone();

This works great, leaving all the rest of the code the same.