Apex Trigger creating duplicate records - Help using trigger.oldmap and trigger.newmap

Question

I'm hoping someone can help me with an issue I have regarding an Apex Trigger that creates a child record when a field of its corresponding master record is set to a particular value. The master object is Opportunity and the child record is a custom object called Ad_Ops_Task__c. My problem is that the following code creates duplicates of the child record when the Opportunity field is set to the value specified in my code below:

trigger CreateAdOpsTask on Opportunity (after update) 
{
    List <Ad_Ops_Task__c> Ad_Ops_Tasks = new List <Ad_Ops_Task__c> ();
    for(Opportunity a: Trigger.new)
        {
        if(a.StageName=='Ad6 - IO Received')
            {
            Ad_Ops_Task__c AOSTask = new Ad_Ops_Task__c ();
            AOSTask.Opportunity__c = a.Id;
            AOSTask.Name = 'AdOps Task - ' + a.Name + ' - ' + a.Media_Plan_Id__c;
            Ad_Ops_Tasks.add(AOSTask);
            }
        }
insert Ad_Ops_Tasks;
}

Answer 1

In addition to comparing the old stagename to the new stagename, you need to ensure that your logic only fires once. Create a class like

public class CreateAdOpsTaskTriggerContext {
  public static boolean executeTrigger=true;
}

Modify your trigger to check the value before executing your logic and then set the executeTrigger variable to false at the end of your logic.

trigger CreateAdOpsTask on Opportunity (after update) {
   if (CreateAdOpsTaskTriggerContext.executeTrigger){
      List <Ad_Ops_Task__c> Ad_Ops_Tasks = new List <Ad_Ops_Task__c> ();

      for (Opportunity oppty: Trigger.new) {

         // get the record out of the oldMap for comparison
         Opportunity oldOppty = (Opportunity)Trigger.oldMap.get(oppty.id);

         // only run this code if the opportunity is in the correct stage, and the stagename has been modified
         if (oppty.StageName == 'Ad6 - IO Received' && oppty.StageName != oldOppty.StageName) {
            Ad_Ops_Task__c AOSTask = new Ad_Ops_Task__c ();
            AOSTask.Opportunity__c = oppty.Id;
            AOSTask.Name = 'AdOps Task - ' + oppty.Name + ' - ' + oppty.Media_Plan_Id__c;
            Ad_Ops_Tasks.add(AOSTask);
         }
      }

      insert Ad_Ops_Tasks;
   }
   CreateAddOpsTaskTriggerContext.executeTrigger = false;
}

Answer 2

I don't think that's what happening.

From looking at your code, I would think that you aren't checking whether there is an Ad_Ops_Task__c object already associated to that opportunity. You should check to see whether one exists for each.

Answer 3

If you want to incorporate the usage of the oldMap to detect if the stagename has changed before creating the child record you can do so like this:

trigger CreateAdOpsTask on Opportunity (after update) {

    List <Ad_Ops_Task__c> Ad_Ops_Tasks = new List <Ad_Ops_Task__c> ();

    for (Opportunity oppty: Trigger.new) {

        // get the record out of the oldMap for comparison
        Opportunity oldOppty = (Opportunity)Trigger.oldMap.get(oppty.id);

        // only run this code if the opportunity is in the correct stage, and the stagename has been modified
        if (oppty.StageName == 'Ad6 - IO Received' && oppty.StageName != oldOppty.StageName) {
            Ad_Ops_Task__c AOSTask = new Ad_Ops_Task__c ();
            AOSTask.Opportunity__c = oppty.Id;
            AOSTask.Name = 'AdOps Task - ' + oppty.Name + ' - ' + oppty.Media_Plan_Id__c;
            Ad_Ops_Tasks.add(AOSTask);
        }
    }

    insert Ad_Ops_Tasks;
}

You should also consider the behavior when the stagename moves "past" this stage... can it revert back to this stage? Should another child record be created at that time? Is that behavior you need to account for in this trigger's logic too?