Populate contact lookup field when Email field is matching with another object

Question

I am going to write a trigger on the Associated Market object. This trigger will use the email address on the Associated Market record and look for a matching email address on the contact record. If a matching email address is found, then the Associated Market record Contact field should be populated with the contact found.

Below is my trigger:

trigger EmailMatchwithContactEmail on Associated_Market__c (before insert) {

   Set<Id> conEmailId = new Set<Id>();

   for(Associated_Market__c assMarket : trigger.New) {
      conEmailId.add(assMarket.Email__c);
   }

   List<contact> conList = [select Id, Email, Name from contact where Email in : conEmailId];

   Map<Id, contact> EmailMatchToContactMap = new Map<Id, contact>();

   for(Associated_Market__c assMarket : conList){
      EmailMatchToContactMap.put(assMarket.Email__c, assMarket);
   }

   for(Contact c : conList) {
       if(c.Email != null){
           c.Name = EmailMatchToContactMap.get(c.Email).id;
       }
   }
}

Answer 1

I create a Map to store the Associated Market by Email. After that i get the existing contacts with the Email in the map's keyset. And I associate the contact's id to associated Market.

Code bellow:

trigger EmailMatchwithContactEmail on Associated_Market__c (before insert) {
    Map<String,Associated_Market__c[]> assotiactedMarketByEmail = new Map<String,Associated_Market__c[]>();

    for(Associated_Market__c assMarket : trigger.New) {
        if(!assotiactedMarketByEmail.containsKey(assMarket.Email__c)){
            assotiactedMarketByEmail.put(assMarket.Email__c, new Associated_Market__c[]{});
        }

        assotiactedMarketByEmail.get(assMarket.Email__c).add(assMarket);
    }

    for(Contact c : [select Id, Email, Name from contact where Email in : assotiactedMarketByEmail.keySet()]){
        for(Associated_Market__c assMarket : assotiactedMarketByEmail.get(c.Email)){
            assMarket.Contact__c = c.Id;
        }
    }
}

Answer 2

This is because you have used map in EmailMatchToContactMap. You should use Map when you are storing "Emails" in the key of the map.

Thanks!

Answer 3

I agree with the Torsen answer but i have done by another trigger have a look into it

trigger EmailMatchwithContactEmail on Associated_Market__c (before insert) {

    set<string> assotiactedMarketByEmail = new set<string>();
    Map<String, String> contactEmailIdMap = new Map<String, String>();

    for(Associated_Market__c assMarket : trigger.New) {
        assotiactedMarketByEmail.add(assMarket.Email__c);
    }

    for(Contact c : [select Id, Email, Name from contact where Email in : assotiactedMarketByEmail Limit 10000]){
        contactEmailIdMap.put(c.Email,c.Id);
    }

    for(Associated_Market__c assMarket : trigger.New){
        assMarket.Contact__c = contactEmailIdMap.get(assMarket.Email__c);
    }
}

Answer 4

trigger EmailMatchwithContactEmail on Associated_Market__c(before insert) {
   Set<String> allEmails = new Set<String>();

   for(Associated_Market__c newAssociate : Trigger.new) {
      if(newAssociate.Email__c != null || newAssociate.Email__c != ' ') {
          allEmails.add(newAssociate.Email__c);
      }
   }

   List<Contact> lstContacts = [select Id, Name, Email from Contact where Email In :allEmails];

   Map<String, Contact> emailToContactMap = new Map<String, Contact>();
   for (Contact contactIterate : lstContacts) {
      emailToContactMap.put(contactIterate.Email, contactIterate);
  }

  for(Associated_Market__c newAssociate : Trigger.new) {
      if(newAssociate.Email__c != null || newAssociate.Email__c != ' ') {
          Contact contactVar = emailToContactMap.get(newAssociate.Email__c);
          if(contactVar != null) {
             newAssociate.Contact__c = contactVar.Id;
          }
      }
   }
}