0

We have a landing page that exists within our ExactTarget account and we would like to pass values to an external landing page. Is there a way, either through the url or another method, to pass multiple values to an external landing page? Sample data would be:

Patient1 ID, Patient1 Action, Patient2 ID, Patient2 Action

3
  • 1
    use parameters - e.g. www.example.com?P1=Patient1&P2=Pationt2. You should be able to use AMPscript or SSJS to pull the info from the DE onto the URL. Or you can also do a POST or get with those to hide them from plain view. For security, I would at least encode them in Base64. Commented Jul 23, 2015 at 19:32
  • Would it be possible to loop through the dataset and append each record? So if we have multiple patients and have request parameter PatientID, I'd want assign multiple patient id's without having to set each individual id.
    – Realrx7
    Commented Jul 24, 2015 at 12:24
  • I think maybe through SSJS for a more dynamic solution. Commented Jul 24, 2015 at 15:30

1 Answer 1

1

Sure. You can just do a string concat() of the URL parameters based on some data source:

%%[
var @rows, @row, @rowCount, @numRows, @zip, @i, @url

set @zip = "55555"
set @numRows = 0 /* 0 means all */
set @rows = LookupOrderedRows("PatientInfo",@numRows,"patientID desc, patientAction asc","patientZip", @zip)
set @rowCount = rowcount(@rows)

if @rowCount > 0 then

    set @url = "http://externalurl.com"

    for @i = 1 to @rowCount do

        var @patientID, @patientAction
        set @row = row(@rows,@i) 
        set @patientID = field(@row,"patientID")
        set @patientAction = field(@row,"patientAction")

        set @url = iif(@i==1,concat(@url,"?"),concat(@url,"&"))
        set @url = concat(@url,"patient",@i,"ID=", @patientID)
        set @url = concat(@url,"&patient",@i,"Action=", @patientAction)

    next @i 
else
    outputLine(concat("No patients found"))
endif 

]%%
<a href="%%=redirectto(@url)=%%">external URL</a>

You must log in to answer this question.

Not the answer you're looking for? Browse other questions tagged .