Get Data from batch iterable

Question

Good day everyone,

Maybe this question is basic for everyone but I'm having a problem with it, so I'm asking for help. I have created a BATCH ITERABLE .

global with sharing class batchProcessor implements Database.batchable<String>, Database.Stateful
{
global Iterable<String> start(Database.batchableContext batchableContext)
   { 
     // m_csvFile is blob data in csv file
       return new CSVIterator(m_csvFile.toString(), Parser.crlf);
   }
   global void execute(Database.BatchableContext batchableContext, List<String> scope)  
   {
      // I want to get the first row of the csv or the header for mapping
      System.debug(scope[0]);
   }
}

This is also my CSVIterator.class

global with sharing class CSVIterator implements Iterator<String>, Iterable<String>
{
   private String m_CSVData;
   private String m_introValue;
   public CSVIterator(String fileData, String introValue)
   {
      m_CSVData = fileData;
      m_introValue = introValue; 
   }
   global Boolean hasNext()
   {
      return m_CSVData.length() > 1 ? true : false;
   }
   global String next()
   {
      String row = m_CSVData.subString(0, m_CSVData.indexOf(m_introValue));
      m_CSVData = m_CSVData.subString(m_CSVData.indexOf(m_introValue) + m_introValue.length(),m_CSVData.length());
      return row;
   }
   global Iterator<String> Iterator()
   {
      return this;   
   }
}

What i want to get at the moment is the first row of the iterable which is the csv header. As you've seen in my batch class i try to System.debug the scope[0] but the result is not the csv header ? How will i do it ?

Pls help.

Thank you !!!

Answer 1

The execute method will be called multiple times with the next batch of rows so you need to grab the first row on the first call to the execute. Because you have the marker interface Database.Stateful, any fields you add to the class will then be preserved between batches:

public with sharing class batchProcessor implements
        Database.Batchable<String>, Database.Stateful {
    ...
    // Will be preserved between execute calls
    private String[] headings;
    ...
    public void execute(Database.BatchableContext bc, List<String> scope) {
        // If variable is null it's the first batch
        if (headings == null) {
            headings = scope[0].split(',');
        }
        ....
    }
    ...
}

Note that the code no longer needs to be global and public is usually the appropriate choice.