Basic Trigger Help

Question

Could someone help me with this basic trigger? When a new task is inserted, I want to update the Status field in the lead to match the CallResult field in the Task. Here is my broken code:

trigger callResult on Task (after insert) 
{
     for (Task task : Trigger.new)
     {
           if (task.Who != null)
           {
                String leadName = task.Who.Id;
                String callResult = task.CallDisposition;

                List<Lead> relatedLead = [SELECT Id, Status FROM Lead WHERE Name = :leadName LIMIT 1];

                if (relatedLead.size() > 0)
                {
                    relatedLead[0].Status = callResult;                  
                }

           }
     }

Answer 1

Here is a shorter (untested) solution:

trigger OnTaskInsertUpdateLeadStatus on Task (after insert) {
    Map<Id, Lead> m = new Map<Id, Lead>();
    for (Task t : Trigger.new) {
         if (t.WhoId != null && t.WhoId.getSObjectType() == Lead.SObjectType) {
             m.put(t.WhoId, new Lead(Id = t.WhoId, Status = t.CallDisposition));
         }
    }
    update m.values();
}

with some opinions:

• The signature of the trigger - the after insert - determines when the trigger is called so no need to double check in the body of the trigger.
• It's unlikely (but possible when a bulk update is done) that multiple Tasks related to the same Lead are handled in the trigger so for safety the map ensures only one reference to the Lead in the update.
• Id values know the type of object they reference so you can stick to a strongly type SObjectType comparison rather than using describe calls and string prefix comparisons.
• Only handle exceptions when you have a clear reason to do so: most exception handling code is counter productive.
• It's been may API versions since updating an empty list counted against governor limits; empty list guards are not needed.
• Move logic out of a trigger into a separate class when you have reason to do so. The benefits must outweigh the reduced cohesion.

Answer 2

You need to perform a DML operation in order to update the leads. You should move this logic out into an Apex Class. Note below that you do not need to query for records to update if you already have their Id.

public static final String LEAD_PREFIX = Lead.sObjectType().getDescribe().getKeyPrefix();

public static void updateLeads(List<Task> tasks)
{
    List<Lead> leads = new List<Lead>();
    for (Task task : tasks)
    {
        if (isLeadId(task.WhoId))
            leads.add(new Lead(Id=task.WhoId, Status=task.CallDisposition));
    }
    if (leads.isEmpty()) return;

    try
    {
        update leads;
    }
    catch (DmlException dmx)
    {
        // map errors back to tasks
        // exercise left to reader
    }
}
public static Boolean isLeadId(Id candidate)
{
    return String.isNotBlank(candidate) &&
        String.valueOf(candidate).startsWith(LEAD_PREFIX);
}

From your Apex Trigger, calling the above is fairly simple. Let's say you called your class TaskServices.

trigger callResult on Task (after insert)
{
    if (trigger.isAfter && trigger.isInsert)
    {
        TaskServices.updateLeads(trigger.new);
    }
}