Not Serializable: System.Http exception on Schedulable class

Question

I have a Schedulable class that calls out to a third party GPS service. The problem I'm running into is that when I try to do the initial schedule (via anonymous execution) I get the error:

Not Serializable: System.Http

Is there something I can do to get around it? I need to schedule this code to run every 90 seconds so I can have a near real time display of all of our vehicles' GPS positions. For what it's worth, here's the code:

global class vNextGpsScheduledUpdate implements Schedulable {
    private vNextGps gps = new vNextGps('username', 'password');

    global void execute(
        SchedulableContext sc1) {
        if (sc1 == null) {
            return;
        }

        /// Get a list of vehicles in the GPS service
        List<vNextGpsVehiclesLocation> l2 = gps.getVehiclesLocations();

        /// Get a list of vehicles in the database
        List<vNextVehicle__c> l1 = getVehiclesFromDb();

        /// Loop through each vehicle in the database
        for (vNextVehicle__c v1 : l1) {
            /// Loop through each vehicle in the GPS service
            for (vNextGpsVehiclesLocation v2 : l2) {
                if (v1.Name == v2.name) {
                    v1.GPS_Coordinates__Latitude__s = v2.latitude;
                    v1.GPS_Coordinates__Longitude__s = v2.longitude;
                    v1.GPS_Timestamp__c = v2.timestamp;
                    v1.Odometer__c = v2.odometer;

                    /// Break out of the inner loop if the name matches
                    break;
                }
            }
        }

        /// Update all vehicles in the database
        update l1;

        /// Schedule the next run of this job
        DateTime a1 = DateTime.now().addSeconds(90);                        /// nextRun
        String b1 = String.valueOf(a1.minute()),                            /// minute
               b2 = String.valueOf(a1.second()),                            /// second
               b3 = b1 + ' ' + b2 + ' * * * ? * vNextGpsScheduledUpdate',   /// cronValue
               b4 = 'vNextGpsScheduledUpdate ' + a1.format('hh:mm');        /// jobName

        vNextGpsScheduledUpdate c1 = new vNextGpsScheduledUpdate();

        System.schedule(b4, b3, c1);
        System.abortJob(sc1.getTriggerId());
    }

    @testVisible
    private List<vNextVehicle__c> getVehiclesFromDb() {
        return [
            SELECT  Name,
                    GPS_Coordinates__Latitude__s,
                    GPS_Coordinates__Longitude__s,
                    GPS_Timestamp__c,
                    Odometer__c
            FROM    vNextVehicle__c
            WHERE   (Is_Active__c = true)
                    AND (GPS_Active__c = true)
        ];
    }
}

UPDATE

I managed to get it working using @sfdcfox's answer. In my original version, I had an inner class in my vNextGps class that I used to mimic C#'s WebClient class since I was porting the code from pre-existing C# code. Because of that the scheduler couldn't serialize the class. I have since removed the inner class and merged the functionality directly into the method that needed it.

Sadly, that was still not enough because the scheduler then complained about calling out. To resolve that issue I moved the call out code into a separate Queueable class. In turn the Scheduleable class now just adds it to the queue, and schedules itself again. So far, the Queueable class is being processed almost immediately thereafter, so the end result is what I needed. Oh, I did have to annotate the Queueable methods with @future (Callout = true) for everything to finally work.

Way too much hoop jumping to get it to work, but at least it works now.

Answer 1

Your vNextGps class has a Http variable as an instance variable. This is causing the vNextGps to fail to serialize. Move the variable to within the function that needs it.

Answer 2

I see few problem in your code :

1. You are trying to schedule class inside execute method itself. It should be executed from Anonymous code or some other place. Check answer to Question 50 here.

2. crone statement doesn't seems right. You can use this website to create crone statement.

3. You are aborting job just after schedule.

4. and most important (that is reason for your error I guess), If your code is doing any callout it must be used with Queueable interface or @future annotation.

Here is updated code (I didnt tested it, as i am not aware about complete functionality) :

global class vNextGpsScheduledUpdate implements Schedulable { private vNextGps gps = new vNextGps('username', 'password');

global void execute( SchedulableContext sc1) {
    if (sc1 == null) {
        return;
    }

    /// Get a list of vehicles in the GPS service
    List<vNextGpsVehiclesLocation> l2 = gps.getVehiclesLocations();

    /// Get a list of vehicles in the database
    List<vNextVehicle__c> l1 = getVehiclesFromDb();

    /// Loop through each vehicle in the database
    for (vNextVehicle__c v1 : l1) {
        /// Loop through each vehicle in the GPS service
        for (vNextGpsVehiclesLocation v2 : l2) {
            if (v1.Name == v2.name) {
                v1.GPS_Coordinates__Latitude__s = v2.latitude;
                v1.GPS_Coordinates__Longitude__s = v2.longitude;
                v1.GPS_Timestamp__c = v2.timestamp;
                v1.Odometer__c = v2.odometer;

                /// Break out of the inner loop if the name matches
                break;
            }
        }
    }

    /// Update all vehicles in the database
    update l1; 

} 

   @testVisible
private List<vNextVehicle__c> getVehiclesFromDb() {
    return [
        SELECT  Name,
                GPS_Coordinates__Latitude__s,
                GPS_Coordinates__Longitude__s,
                GPS_Timestamp__c,
                Odometer__c
        FROM    vNextVehicle__c
        WHERE   (Is_Active__c = true)
                AND (GPS_Active__c = true)
    ];
}    
}

Execute below code from anonymous window of developer console :

vNextGpsScheduledUpdate c1 = new vNextGpsScheduledUpdate(); 
//You will need to change this statement
String sch = '20 30 8 10 2 ?';         
System.schedule('vNextGpsScheduledUpdate', sch, c1);

You can read this article to get familiar with this concept.