Insert Task.whoId (before insert)

Question

I'm having problens with a trigger that is supposed to add a hardcoded contact ID before the task is inserted. I've arrived to the point where I'm adding the Who ID to the task, but it never works.

The code:

public static void setTaskWhoid (List<Task> tasklist){
    Set<Id> idMain = new Set<Id>();
    string textId;
    for (task tarefa: tasklist){
        if(tarefa.WhatId != NULL){
            textId = tarefa.WhatId;
        }
        if(textId != NULL && textId.startsWith('500')){
            idMain.add(tarefa.WhatId);
        }
    }
    if(idMain.size() > 0){
        List<Case> caselist = [SELECT Id, AccountId FROM Case WHERE Id IN: idMain];
        Map <Id,Id> mapCase = new Map<Id,Id>();
        for(Case caso: caselist){
            system.debug('Account ID'+caso.AccountId);
            if(caso.AccountId == '001c000000fxTF8'){
            mapCase.put(caso.AccountId, '003c000000XEZfU');
            }
            for (task tarefa: tasklist){
                system.debug('WhoID:' + mapCase.get(caso.AccountId));
                tarefa.WhoId = mapCase.get(caso.AccountId);
            }
        }
    }
}

I've add 2 debugs to check if it's getting eveything correctly, and so far so good, but my problem is that even after I add a WhoId to the task nothing appears in the actual task page.

Any help is appreciated.

EDIT: I've tried changing the trigger to 'after insert' and add a upsert at the end of the code, it returned the following error TaskWhoID: execution of AfterInsert caused by: System.FinalException: Record is read-only: Class.TaskWhoID.setTaskWhoid: line 24, column 1, line 24 is tarefa.WhoId = mapCase.get(caso.AccountId);

EDIT 2: Due to Request here is the trigger code:

trigger TaskWhoID on Task (before insert) {
    TaskWhoID.setTaskWhoid(Trigger.new);
}

EDIT 3: Might've found the problem, according to this site if I have shared activities turned on i can't update task.whoid field before insert/update, and task.whoid cannot be updated after insert/update. I've created a request for them to turn shared activities off and will answer after tests.

Answer 1

If you are always using the same Contact, there is no need for a map.

Aside from the best practices listed below, your aims are unclear. Do you mean to replace every WhoId or only the Case WhoIds? Right now it looks like you are taking all Tasks that look up to an Case and if that Case looks up to a particular Account, replace the WhoId with a particular Contact. In all other situations, it looks like you will be inserting null into the WhoId. You will even insert null sometimes if you insert multiple tasks related to Cases, some of which are not to the Account you are looking for.

RECOMMENDED PRACTICE: Take advantage of static types. Compare SObjectType directly:

if (tarefa.WhatId != null && tarefa.WhatId.getSObjectType() == Case.SObjectType)
{
    caseIds.add(tarefa.WhatId);
}

BEST PRACTICE: Never use hard coded Ids. Query (and lazy load) your data like so.

static Account importantAccount
{
    get
    {
        if (importantAccount == null)
        {
            List<Account> potentialAccounts = [SELECT Id FROM Account];
            // WHERE someUniqueField = someUniqueValue
            if (!potentialAccounts.isEmpty()) importantAccount = potentialAccounts[0];
        }
        return importantAccount;
    }
    private set;
}

static Contact importantContact
{
    get
    {
        if (importantContact == null)
        {
            List<Contact> potentialContacts = [SELECT Id FROM Contact];
            // WHERE someUniqueField = someUniqueValue
            if (!potentialContacts.isEmpty()) importantContact = potentialContacts [0];
        }
        return importantContact;
    }
    private set;
}

BEST PRACTICE: Don't nest for loops. You are not using any Case information in your Task loop. Separate them.

for (Case caso : caseList)
{
    //do stuff
}
for (Task tarefa : taskList)
{
    //do stuff
}

Answer 2

So regarding my 3rd edit, It was correct, the code was working correctly.

The problem lies in that I can't update the Task.WhoId before the insert if the feature Shared Activities is enabled.

Fields not updated.

Thanks for the help.

Answer 3

string textId;

It appears to me that you're using 15 character strings for your ID's. Try converting them to Id's by using ID.valueOf(String) and see if that doesn't solve your problem.