Issue with updating objects using the "accessLevel" parameter of Database.update method

Question

We are updating our code to use the new accessLevel parameter in the update method of the Database class. We have cases where the object contains fields that cannot be edited (e.g. LastModifiedDate).

If we update the object using the normal update, the update works because we have not actually updated LastModifiedDate. However, if we use Database.update with AccessLevel.USER_MODE, we see the exception:

System.DmlException: Operation failed due to fields being inaccessible on Sobject Account, check errors on Exception or Result!

Sample code we have used is as below. The debug message prints: The field(s) "LastModifiedDate" are not accessible for update of Account

Account acc = new Account(name='Acc1');
insert acc;

acc = [select id, name, lastModifiedDate from Account where id = :acc.id];
acc.name = 'Acc1_updated';
update acc;

try {
    Database.update(acc, AccessLevel.USER_MODE);
} catch (DMLException dex) {
    System.debug('The field(s) "' + 
    String.join(dex.getDmlFieldNames(0), ', ') + '" are not accessible for update of Account');
    throw dex;
}

Similar issue with auto numbered name fields, formula fields, master-detail lookup fields etc.

Is there any way to use Database.update to update the object other than removing the field LastModifiedDate from the SOQL query select list? Any pointers will be appreciated.

Answer 1

As you have seen, you cannot include LastModifiedDate when doing an update in user mode. The easiest way to fix this would be to create a new Account in Apex and use that to update. For example:

acc = [SELECT Id, Name, LastModifiedDate FROM Account WHERE Id = :accId];
Account accountToUpdate = new Account(Id = accId, Name = 'Acc1_updated');
update as user accountToUpdate;

An alternative way to do this would be to use the stripInaccessible method. For example:

List<Account> accList = [SELECT Id, Name, LastModifiedDate FROM Account WHERE Id = :accId];
accList[0].Name = 'Acc1_updated';
Account accToUpdate = Security.stripInaccessible(AccessType.UPDATEABLE, accList).getRecords()[0];
update as user accToUpdate;