IF with ISPICKVAL formula

Question

I'm trying to create a formula that calls for picklist values if a field contains that data. Unfortunately I seem to have a syntax error. Can you take a look and tell me what is wrong?

IF(
    ISPICKVAL(central__c, 'APEX'),
    0Y209000000TcxiCAC
)
)
IF(
    ISPICKVAL(central__c, 'INDEPENDANT'),
    0Y209000000TcybCAC
)
),
NULL
)
)

Answer 1

There's a time to use ISPICKVAL, and a time not to. This is one of those times when you shouldn't. CASE is easier to read and maintain, so it should be preferred in this case.

CASE(central__c, 
'APEX', '0Y209000000TcxiCAC',
'INDEPENDANT', '0Y209000000TcybCAC',
NULL
)

Note that your most likely syntax problem were the missing quotes around ID values. You must always enclose strings in quotes. The three main types of data that don't use quotes are numbers, Boolean values (true/false), and null.

Answer 2

I can't really tell what exactly you're trying to do here, but assuming that the formula would be semantically correct if the syntax errors were fixed... it'd look like this

IF(
    ISPICKVAL(central__c, 'APEX'),
    /* Strings need to be enclosed in quotes (either single or double quotes, not */
    /* "smart" quotes) */
    /* You also need a comma after each argument */
    '0Y209000000TcxiCAC',

    /* The way to do an if-else in a formula is to nest another IF() in the 3rd argument */
    IF(
        ISPICKVAL(central__c, 'INDEPENDANT'),
        '0Y209000000TcybCAC',
        /* IF() requires 3 arguments, no more, no less */
        null
    )
)

Note the placement and usage of closing parenthesis and commas. Close paren ends a function (or a logical grouping like 2 * (3 + 4) for specifying the order of evaluation). Commas are used between arguments to a function.

While that should be syntactically correct, that's a rather obtuse way to test a single field against multiple values. A better choice here would be the CASE() function.

CASE(
    /* The first argument is always the expression to match the values listed below against */
    /* CASE() is also one of the few things that can work on picklists directly */
    Central__c,

    /* Next up, value - result pairs */
    'APEX', '0Y209000000TcxiCAC',
    'INDEPENDANT', '0Y209000000TcybCAC',

    /* Finally, the result to yield if there are no value matches */
    null
)

I've included extra blank lines here in the hope that it makes things easier to read.