After delete trigger is not firing< but code in anonymous works properly

Question

I have Active_Contacts__c Decimal field in Account and Active__c checkbox in Contact, also created ContactTrigger and ContactTrigger handler. I have already created logic for after update event and it works properly, but after delete event is not firing and nothing happens, though same code is working in anonymous.

Code below:

trigger ContactTrigger on Contact (after insert, after update, after delete, after undelete) {
   switch on Trigger.operationType {
       when AFTER_INSERT {
           //
       }
       when AFTER_UPDATE {
           ContactTriggerHandler.afterUpdate(Trigger.newMap, Trigger.oldMap);
       }
       when AFTER_DELETE {
           ContactTriggerHandler.afterDelete(Trigger.oldMap);
       }
       when AFTER_UNDELETE {
           //
       }
   }
}
___________________________________________________________________________________

public with sharing class ContactTriggerHandler {
   public static void afterUpdate(Map<Id, SObject> newMap, Map<Id, SObject> oldMap) {
       Contact temp1;
       Contact temp2;
       List<Contact> updatedContact = new List<Contact>();
       for (Id contId : newMap.keySet()) {
           temp1 = (Contact) newMap.get(contId);
           temp2 = (Contact) oldMap.get(contId);
           if (temp1.Active__c != temp2.Active__c) {
               updatedContact.add(temp1);
           }
       }
       if (updatedContact != null) {
           countContactsRelatedToAccsIfUpdate(updatedContact);
       }

   }
   
   public static void afterDelete(Map<Id, SObject> oldMap) {
       countContactsRelatedToAccsIfDel(oldMap);
   }
   
   private static void countContactsRelatedToAccsIfUpdate(List<Contact> contacts) {
       Set<Id> ids = new Set<Id>();
       for (Contact cont : contacts){
               ids.add(cont.AccountId);
       }
       List<Account> accounts = [SELECT Id, Active_Contacts__c, (SELECT Active__c FROM Contacts) FROM Account WHERE Id IN :ids ];
       for(Account acc : accounts){
           for(Contact cont: contacts){
               if(cont.AccountId == acc.Id){
                   if (cont.Active__c == true) {
                       acc.Active_Contacts__c += 1;
                   } else if (cont.Active__c == false) {
                       acc.Active_Contacts__c -= 1;
                   }
               }
           }
       }
       update accounts;
   }

   private static void countContactsRelatedToAccsIfDel(Map<Id, SObject> oldContactsMap) {
       Set<Id> contactsIds = oldContactsMap.keySet();
       for (Contact cont : [SELECT Id FROM Contact]){
           if (contactsIds.contains(cont.Id)){
               contactsIds.remove(cont.Id);
           }
       }
       List<Contact> contacts = [SELECT AccountId, Active__c FROM Contact WHERE Id = :contactsIds];
       List<Account> accounts = [SELECT Active_Contacts__c FROM Account WHERE Id IN (SELECT AccountId FROM Contact WHERE Id = :contactsIds)];
       for (Account acc : accounts){
           for(Contact cont : contacts){
               if(cont.AccountId == acc.Id && cont.Active__c == true){
                   acc.Active_Contacts__c -= 1;
               }
           }
       }
       update accounts;
   }

Answer 1

You can generate one method to do all of this, in far less code:

public static void updateActiveContactCount(
    Contact[] oldRecords, 
    Contact[] newRecords) {
    Map<Id, Account> updatedAccounts = new Map<Id, Account>();
    if(oldRecords != null) {
        for(Contact record: oldRecords) {
            updatedAccounts.put(
                record.AccountId, 
                new Account(Id=record.AccountId,Active_Contacts__c=0)
            );
        } 
    }
    if(newRecords != null) {
        for(Contact record: newRecords) {
            updatedAccounts.put(
                record.AccountId, 
                new Account(Id=record.AccountId,Active_Contacts__c=0)
            );
        }
    }
    for(AggregateResult result: [SELECT COUNT(Id) sum, AccountId Id FROM Contact WHERE AccountId = :updatedAccounts.keySet() AND Active__c = TRUE]) {
        updatedAccounts.get((Id)result.get('Id')).Active_Contacts__c = (Integer)result.get('sum');
    }
    update updatedAccounts.values();
}

You can call this simply as:

ContactTriggerHandler.updateActiveContactCount(Trigger.old, Trigger.new);

And yes, you should trigger this for insert, update, delete, and undelete.

Alternatively, consider just using DLRS. It's built to handle this type of scenario for you automatically with just clicks instead of code.