Apex Test - Instantiate new Controller

Question

I am trying to instantiate a new controller. But every syntax I have tried shows an error.

Here is my code:

Class:

public  class MyNewCaseController {
    
    public string filterId {get; set;}
    
    public MyNewCaseController(ApexPages.StandardController  ctrl){
        string filter = ApexPages.currentPage().getParameters().get('filterId');
        if (filter != null)
            filterId = filter;
    }
}

Test:

@isTest
public without sharing class MyNewCaseListControllerTest {
    
    @isTest
    public static void testMyNewCaseController (){
        // Instantiate a new controller with all parameters in the page
        MyNewCaseListController controller = new MyNewCaseListController.MyNewCaseListController(ApexPages.StandardController ctrl);
 
    // Do something
    }
}

I get the error “Invalid type: MyNewCaseListController.MyNewCaseListController”.

If I try just

MyNewCaseListController controller = new MyNewCaseListController();

I get Constructor not defined: [MyNewCaseListController].()

If I try

MyNewCaseListController.MyNewCaseListController();

I get “Invalid type: MyNewCaseListController.MyNewCaseListController”

If I try

MyNewCaseListController controller = new MyNewCaseListController.MyNewCaseListController(ApexPages.ctrl);

I get “Invalid type: MyNewCaseListController.MyNewCaseListController”

What am I doing wrong?

Answer 1

The (datatype name, datatype name, ...) syntax is for defining a function's parameter list. To call it, you simply pass in the parameters. As a simple example:

class Counter {
  Integer value;
  Counter(Integer initialVal) {
    value = initialVal;
  }
  void increment() {
    value++;
  }
}

You would construct it as:

Integer initialValue = 5;
Counter theCounter = new Counter(initialValue);

If you replace Integer in our example with an ApexPages.StandardController, you can see it works almost the exact same way:

class Controller {
  ApexPages.StandardController value;
  Controller(ApexPages.StandardController initialVal) {
    value = initialVal;
  }
  ApexPages.StandardController redirect() {
    value.setRedirect(true);
    return value;
  }
}

And we'd call it in very much the same manner:

Account record = new Account();
ApexPages.StandardController standardController = new ApexPages.StandardController(record);
Controller extensionController = new Controller(standardController);

As you can see, we don't call the constructor directly; the new operator implies that the constructor will be called, and the specific constructor that will be called will depend on the order, number, and data types of the parameters provided.

Note that all classes get an "implicit" zero-argument constructor by default, unless we define our own. For example:

class A {
}
A value = new A(); // Okay!

class B {
  B(Integer value) {
  }
}
B value1 = new B(5); // Okay!
B value2 = new B(); // No zero-arg constructor available!

class C {
  C() {
  }
  C(Integer value) {
  }
}
C value1 = new C(5); // Okay!
C value2 = new C(); // Okay!
C value3 = new C(5, 10); // No such constructor.
C value4 = new C('Hello World'); // no such constructor.

As such, you always need to pay attention to the data types and number of parameters.