Ampscript error - unsure how to troubleshoot

Question

Getting this error: 'A variable name is not a valid because contains illegal characters. Variable names must begin with the @ symbol followed by one or more letters, numbers, or underscores. Variable Name: <' When trying to run this AMPscript code - the '<' symbol is not in

%%[ var @rows, @row, @rowCount, @numRowsToReturn, @lookupValue, @i, @Pricebookname

set @lookupValue = AttributeValue("Name") 
set @numRowsToReturn = 0 
set @rows = LookupOrderedRows("SalesforceApplication_Website",@numRowsToReturn,"Pricebook_Name__c
 asc","Name", @lookupValue) ]%% 

%%[ set @rowCount = rowcount(@rows) 

if @rowCount > 0 then

for @i = 1 TO @rowCount do

set @row = row(@rows,@i) 
set @Pricebookname = field(@row, "Pricebook_Name__c")


IF (@Pricebookname == 'city Low') then 

%%=AttachFile(Contentbuilder,445768)=%%

elseif (@Pricebookname == '43in B') then 

%%=AttachFile(Contentbuilder,445765)=%%

elseif (@Pricebookname == 'B saver') then

%%=AttachFile(Contentbuilder,445764)=%%

elseif (@Pricebookname == 'Nat G User - 2022') then 

%%=AttachFile(Contentbuilder,445763)=%%


EndiF ]%% 

%%[ next @i ]%% 
%%[ else ]%% 
%%[ endif ]%%

Any help is much appreciated

Answer 1

There are multiple issues here, but let's start with the core one - the illegal < characters in variable names. You probably wrote your code in the Content tab instead of the HTML Editor of your block and some HTML like <br>, &nbsp;<br> were added by the editor to break the lines of the content.

Check your code here:

and there you will probably find the illegal characters with added HTML tags.

It's a good practice to write your code in the HTML editor or simply in the Code Snippet content blocks which won't add extra HTML.

Other than that, as Vishal Kumar C V mentioned in his comment, you are using inline Ampscript in a code block, so code like this %%=AttachFile(Contentbuilder,445765)=%% should be changed to AttachFile(Contentbuilder,445765).

You're actually opening and closing the script block needlessly here - since you don't output anything as visible HTML and just adding attachments, all of this could be stored in a single block like this:

%%[ var @rows, @row, @rowCount, @numRowsToReturn, @lookupValue, @i, @Pricebookname

set @lookupValue = AttributeValue("Name") 
set @numRowsToReturn = 0 
set @rows = LookupOrderedRows("SalesforceApplication_Website",@numRowsToReturn,"Pricebook_Name__c
 asc","Name", @lookupValue) 

set @rowCount = rowcount(@rows) 

IF @rowCount > 0 THEN

    FOR @i = 1 TO @rowCount DO

        set @row = row(@rows,@i) 
        set @Pricebookname = field(@row, "Pricebook_Name__c")

        IF (@Pricebookname == 'city Low') THEN 
            AttachFile(Contentbuilder,445768)

        ELSEIF (@Pricebookname == '43in B') THEN 
            AttachFile(Contentbuilder,445765)

        ELSEIF (@Pricebookname == 'B saver') THEN
            AttachFile(Contentbuilder,445764)

        ELSEIF (@Pricebookname == 'Nat G User - 2022') THEN 
            AttachFile(Contentbuilder,445763)

        ENDIF
    NEXT @i
ENDIF
]%%