Flow InvocableAction returning an object with a list of objects

Question

I'm looking to provide a Flow User with a list of Search Results based on a query. I have the following set of code, and haven't been able to figure out how to get it to work. (I've tried moving the classes to their own files, adding them to a Permission Set assigned to the running user).

Once the code below is in an org, I can create a flow that calls the action (say passing an argument of Banana). I can then make a Loop element that loops over results.

My error occurs when I try to reference anything within the Fruit class. I get the error: The "name" field doesn't exist on the "ComplexAction$Fruit" object, or you don't have access to the field.

Any tips on making this work? I have seen this SO post, though my error happens after the screens in the post. How to iterate over List<List<String>> which is returned by Apex, in a flow?

global with sharing class ComplexAction {
  global class Basket { // this is our group of search results
    @InvocableVariable(label='Original Query')
    global String origQuery;
    @InvocableVariable(label='Results')
    global List<Fruit> results;
  }

  global class Fruit {
    @InvocableVariable(label='Fruit Name')
    global String name;
  }

  @InvocableMethod(label='Search for Fruit')
  global static List<Basket> searchForFruit(List<String> criteria) {
    //imagine code that does something useful
    return null; //this doesn't matter for the purpose of this post
  }
}

Answer 1

Want to clarify the previous answer.

You can use this code, but need to create 2 separate classes

global with sharing class ComplexAction {
  global class Basket { // this is our group of search results
    @InvocableVariable(label='Original Query')
    global String origQuery;
    @InvocableVariable(label='Results')
    global List<Fruit> results;
  }
    
  @InvocableMethod(label='Search for Fruit')
  global static List<Basket> searchForFruit(List<String> criteria) {
    //imagine code that does something useful
    return null; //this doesn't matter for the purpose of this post
  }
}

and

global class Fruit {
    @AuraEnabled
    global String name {get; set;}
}

Fruit you can specify as Apex-Defined variable

And inside for Loop put Assignment Action first where assign Loop Current item to your var

PS: Other annotations can’t be used with the InvocableVariable annotation - from documentation. Thanks

Answer 2

I took your code and created a Fruit class on its own file, and just added the @AuraEnabled annotation to it, as suggested by salesforce when you are creating an Apex-Defined variable:

global class Fruit {
    @InvocableVariable
    @AuraEnabled
    global String name;
}

and on the Invocable method, I'm returning a list of list of Fruit, it looks like this:

global with sharing class ComplexAction {
    @InvocableMethod(label='Search for Fruit')
    global static List<List<Fruit>> searchForFruit(List<String> criteria) {
        List<List<Fruit>> results = new List<List<Fruit>>();
        List<Fruit> fruits = new List<Fruit>();
        for (String fruitName : new List<String>{ 'Banana', 'Apple', 'Strawberry' }) {
            Fruit f = new Fruit();
            f.name = fruitName;
            fruits.add(f);
        }
        results.add(fruits);
        return results;
    }
}

and it seems to be working when looping that collection variable on the flow, hope this helps or let me know if you need further details