How do I convert this paypal date format to a valid salesforce date?

Question

Paypal is sending dates to my Rest service in this format 09:30:12 Jan 02, 2022 PST If I use the DateTime.valueOf() function to translate the value to a DateTime field, it fails with an invalid date/time format error.

Is there any built-in functionality in Apex that will help me convert this format to a DateTime field? I am going through the documentation but haven't found anything yet.

The values being sent by Paypal IPN are being sent in the request.params

An example of the params being sent by the IPN.I have captured these in the user debug logs.

USER_DEBUG|[24]|DEBUG|business ==> sb-147na4709042@business.example.com
USER_DEBUG|[24]|DEBUG|payment_status ==> Completed
USER_DEBUG|[24]|DEBUG|mc_currency ==> USD
USER_DEBUG|[24]|DEBUG|shipping_discount ==> 0.00
USER_DEBUG|[24]|DEBUG|txn_type ==> web_accept
USER_DEBUG|[24]|DEBUG|mc_gross ==> 466.78
USER_DEBUG|[24]|DEBUG|ipn_track_id ==> 11eacc648df9b
USER_DEBUG|[24]|DEBUG|payment_date ==> 09:30:12 Jan 02, 2022 PST

Answer 1

There's nothing you can do. Manual parsing is required. This isn't as bad as it sounds though, as you can:

public static DateTime parsePaypalIpnDate(String theDate) {
    String[] months = new String[] { '', 'Jan', 'Feb', 'Mar', 'Apr', 'May', 'Jun', 'Jul', 'Aug', 'Sep', 'Oct', 'Nov', 'Dec' };
    Pattern ipnDatePattern = Pattern.compile('(\\d+):(\\d+):(\\d+) (\\w+) (\\d+), (\\d+) (\\w+)');
    Matcher dateMatcher = ipnDatePattern.matcher(theDate);
    dateMatcher.find();
    Integer hour = Integer.valueOf(dateMatcher.group(1));
    Integer minute = Integer.valueOf(dateMatcher.group(2));
    Integer second = Integer.valueOf(dateMatcher.group(3));
    Integer month = months.indexOf(dateMatcher.group(4));
    Integer day = Integer.valueOf(dateMatcher.group(5));
    Integer year = Integer.valueOf(dateMatcher.group(6));
    String timeZoneName = dateMatcher.group(7);
    TimeZone paypalTimeZone = TimeZone.getTimeZone(timeZoneName);
    DateTime timeAsGmt = DateTime.newInstanceGMT(year, month, day, hour, minute, second);
    Integer timeZoneOffset = paypalTimeZone.getOffSet(timeAsGMT);
    DateTime timeAsIntended = timeAsGmt.addSeconds(timeZoneOffset/1000);
    return timeAsIntended;
}

Note that this might be an hour off when it's within 24 hours of DST changes, when applicable, as I'm not sure there's a valid indicator for DST changes.

Answer 2

I actually started coding along similar lines.

String[] monthList = ',Jan,Feb,Mar,Apr,May,Jun,Jul,Aug,Sep,Oct,Nov,Dec'.split(',');
string wannabeDate = '09:30:12 Jan 02, 2022 PST';
string timePart = wannabeDate.substring(0,8);
System.Debug(timePart);
string datePart = wannabeDate.substring(9,(9+12));
System.Debug(datePart);
string timeZone = wannabeDate.right(3);
System.Debug(timeZone);
System.Debug(datePart.substring(0,3));
integer month = monthList.indexOf(datePart.substring(0,3));
System.Debug('Month ==> ' + month);
string day = datePart.substring(4,6);
System.Debug('Month ==> ' + day);
string year =datepart.right(4);
System.Debug('Year ==> '+ year);
string formNewDate = year+'-'+ string.valueOf(month).leftPad(2,'0') +'-'+day+' '+timePart;
System.Debug(formNewDate);
DateTime dd = Datetime.valueOf(formNewDate);
System.Debug(dd);
String ddwithTz = dd.format(formnewDate,timeZone);
System.Debug(ddwithTz);

I was kind of hoping to avoid this.