Validation Rule : Error: Syntax error. Missing ')'

Question

AND
(Sync_to_system__c
,OR(CONTAINS(Job_Name__c , '\\')
,CONTAINS(Job_Name__c , '/')
,CONTAINS(Job_Name__c , ':')
,CONTAINS(Job_Name__c , '<')
,CONTAINS(Job_Name__c , '>')
,CONTAINS(Job_Name__c , '|')
,CONTAINS(Job_Name__c , '*')
,CONTAINS(Job_Name__c , '?')
,CONTAINS(Job_Name__c , '+')
,CONTAINS(Job_Number__c '#')
,CONTAINS(Job_Name__c , '"')
,BEGINS(Job_Name__c, ' ')
,(RIGHT(Job_Name__c, 1)=' ')
,(RIGHT(Job_Name__c, 1)='.')))

Error: Syntax error. Missing ')'

I must be missing something really obvious but i put it into notepad++ and all the )'s look like they line up just fine,

Sync_to_system__c is a checkbox so I want to check that the box is checked and the job name has something like these.

Answer 1

You are missing a , at Job_Number__c

,CONTAINS(Job_Number__c '#') 

Should be

,CONTAINS(Job_Number__c, '#')

Answer 2

Treating validation formulas like they were normal code and applying indentation tends to really help out on issues like this.

Doing that would look like this

AND(
    Sync_to_system__c,
    OR(
        CONTAINS(Job_Name__c , '\\'),
        CONTAINS(Job_Name__c , '/'),
        CONTAINS(Job_Name__c , ':'),
        CONTAINS(Job_Name__c , '<'),
        CONTAINS(Job_Name__c , '>'),
        CONTAINS(Job_Name__c , '|'),
        CONTAINS(Job_Name__c , '*'),
        CONTAINS(Job_Name__c , '?'),
        CONTAINS(Job_Name__c , '+'),
        CONTAINS(Job_Number__c '#'),
        CONTAINS(Job_Name__c , '"'),
        BEGINS(Job_Name__c, ' '),
        (
            RIGHT(Job_Name__c, 1) = ' '
        ),
        (
            RIGHT(Job_Name__c, 1) = '.'
        )
    )
)

That doesn't seem to indicate anything wrong with parenthesis, but there is an issue with the CONTAINS(Job_Number__c '#'), part.

You're missing a comma in between the arguments to that call to CONTAINS. It's true that it's not a parenthesis, but syntax errors in formulas have a tendency to cascade to generate other issues in the end.

Answer 3

You can heavily optimize this code with REGEX, not to mention some of your conditions are nonsensical, specifically, a field cannot start with or end with a space character. Here's a revised version:

Sync_to_system__c && REGEX(Job_Name__c, '(.*(\\.$))|(.*[\\/:<>|*?+#].*)')

Answer 4

AND( Sync_to_system__c, OR( CONTAINS(Job_Name__c , '\'), CONTAINS(Job_Name__c , '/'), CONTAINS(Job_Name__c , ':'), CONTAINS(Job_Name__c , '<'), CONTAINS(Job_Name__c , '>'), ,CONTAINS(Job_Name__c , '|'), CONTAINS(Job_Name__c , '*'), CONTAINS(Job_Name__c , '?'), ,CONTAINS(Job_Name__c , '+'), CONTAINS(Job_Number__c '#'), CONTAINS(Job_Name__c , '"'), BEGINS(Job_Name__c, ' '), RIGHT(Job_Name__c, 1)=' ', RIGHT(Job_Name__c, 1)='.' ) )

Answer 5

Yikes! Well that looked hideous... but it my defense I wrote it using my phone

Try this

AND( 
Sync_to_system__c, 
OR( 
CONTAINS(Job_Name__c , '\'), 
CONTAINS(Job_Name__c , '/'), 
CONTAINS(Job_Name__c , ':'), 
CONTAINS(Job_Name__c , '<'), 
CONTAINS(Job_Name__c , '>'), 
CONTAINS(Job_Name__c , '|'), 
CONTAINS(Job_Name__c , '*'), 
CONTAINS(Job_Name__c , '?'),
CONTAINS(Job_Name__c , '+'), 
CONTAINS(Job_Number__c '#'), 
CONTAINS(Job_Name__c , '"'), 
BEGINS(Job_Name__c, ' '), 
RIGHT(Job_Name__c, 1)=' ', 
RIGHT(Job_Name__c, 1)='.' 
))