Help with invocable apex method for process builder [closed]

Question

Create apex class that can be lunched from Process Builder (for Account). Apex class should make next logic: When new Account is created, create new Task object with Subject “Negotiations with {Account.Name}”, link created Account with this Task.

public with sharing class AccountProcessBilder {
    @InvocableMethod
    public static void createTask(){
        Task newTask = new Task();
        newTask.Subject = 'Negotiations with ' + Account.Name;
    }
}

Answer 1

You need to use @InvocableVariable, the first example is perfectly suitable for your problem (link to docs). You'll need to create request class, set it as List to method params and left return type as void. Code example is listed below:

public with sharing class AccountProcessBilder {
    public class requestObject {
        @InvocableVariable(required=true label='Account ID')
        public Id accountId;
        @InvocableVariable(required=true label='Account Name')
        public String accountName;
    }

    @InvocableMethod(label='Create Task')
    public static void createTask(List<requestObject> requests) {
        List<Task> toInsert = new List<Task>();
        
        for (requestObject request_i : requests) {
            toInsert.add(new Task(WhatId = request_i.accountId, Subject = 'Negotiations with ' + request_i.accountName));
        }
        
        insert toInsert;       
    }
}