How do I automatically fill in an object field knowing the label?

Question

I have a custom object whose fields correspond to abbreviated currency names.

Exchange Rate (Custom Object)

Fields:

USD - label USD__c - API name

EUR - label EUR__c - API name

I also have a Map that contains information about currency rates, in this form:

{EUR=1.155759, USD=1.417148}

How can I automatically find the corresponding object field based on the currency name from Map and fill it in with the value? I.e. without explicitly specifying: Exchange_Rate__c.USD__c = ...

Answer 1

You can use the put() method of the SObject class to dynamically set field values for a record, but you will need the API name. Something like this should work:

Map<String, Integer> valueByCurrency = new Map<String, Integer> {
    EUR => 1.155759,
    USD => 1.417148
};

for (SObject obj : listOfSObjects) {
    for (String currency : valueByCurrency) {
        String fieldName = currency + '__c';        
        obj.put(fieldName, valueByCurrency.get(currency));    
    }
}

Answer 2

For a given object, you can map the label back to the API field name with a describe call:

public static void setFieldValuesFromJson(sobjectType sourcesObject, sObject record, Map<String, Object> jsonMap) {
  Map<String, sObjectField> fieldLabelToApiName = new Map<String, sObjectField>();
  for(sObjectField field: sourcesObject.getDescribe().fields.getMap().values()) {
    fieldLabelToApiName.put(field.getDescribe().getLabel(), field);
  }
  for(String key: jsonMap.keySet()) {
    record.put(fieldLabelToApiName.get(key), jsonMap.get(key));
  }
}

Where we use sObject.put(sObjectField field, Object value) to place the values into the correct field. Since this is dynamic, be aware that changing the label or translating the field label may break this code.

You can call it using the following notation:

Exchange_Rate__c record = new Exchange_Rate__c(); // Or from a query...
Map<String, Object> jsonMap = (Map<String, Object>)JSON.deserializeUntyped(jsonBody);
setFieldValuesFromJson(Exchange_Rate__c.sobjectType, record, jsonMap);