Get the changed fields on a record?

Question

Is there a quick/scalable/reliable way to get a list of the fields that changed before an update is made to a record? I know i get the bulk (maybe all even) in a before update trigger on the record, but I'm not sure if that would get all them?

Oder of Execution

Answer 1

I think that what you need is something like the method below, you can create a list of Schema.sObjectField to include/exclude certain fields.

In your trigger just call this method with the record Id.

public Schema.sObjectField[] getChangedFields(ID recordId, Schema.sObjectField[] fieldList) {
    Schema.sObjectField[] changedFields = new list<Schema.sObjectField> ();
    SObject o1 = Trigger.oldMap.get(recordId);
    SObject o2 = Trigger.newMap.get(recordId);

    for (Schema.sObjectField field : fieldList) {
        Object v1 = o1.get(field);
        Object v2 = o2.get(field);
        if (didFieldChange(v1, v2)) {
            changedFields.add(field);
        }
    }
    return changedFields;
}

private static Boolean didFieldChange(Object v1, Object v2) {
    if (v1 == null && v2 == null) {
        return false;
    }
    if (v1 != v2) {
        return true;
    }
    return false;
}

Please mark this answer as accepted if this works for you and for the other readers bump up if it helped you.

Answer 2

  /**
  * @description checks whether the updated record values are different from the previous
  * @author Remario Richards | 05-29-2021 
  * @param oldRecord 
  * @param newRecord 
  * @return Set<String> 
  **/
  public static Set<String> GetChangedFields(SObject oldRecord, SObject newRecord) {
    Set<String> fields = new Set<String>();
    Set<String> systemFields = new Set<String>{
      'CreatedDate','LastModifiedById','LastModifiedDate','SystemModstamp'
    };
    for (String key : newRecord.getPopulatedFieldsAsMap().keySet()) {
      if(systemFields.contains(key)) continue;
      if(oldRecord.get(key) != newRecord.get(key)){
        fields.add(key);
      }
    }
    return fields;
  }

Answer 3

In a before update trigger, you can use trigger.old and trigger.new to compare the old and new values/fields. Then you can call another method to store the fields that are changed or process them in anyway you need.

Considering that you want the solution to be scalable before updating, you can schedule an Apex job or Batch Apex for the records that need to be processed (future will not work).

Answer 4

We can get the changed fields by enabling field history tracking. But we can enable history only for 20 fields per object. Then by access history object we can get both old value and new value.