Match Ownership in Duplicate Leads

Question

This is my first question here. I'm working with a company that allows duplicate leads, but they want all the duplicate leads to have the same owner. I'm trying to write a before insert, before update trigger, but I can't make it work. Some help would be awesome!!

Thank you so much!!!

Here's a sample of my trigger.

trigger DuplicateLeadOwner on Lead (before insert, before update) {
String leadEmail;
String leadId;
List <Lead> dupeleads = [SELECT Id, OwnerId FROM Lead WHERE Email = :leadEmail AND Id != :leadId];
for(Lead l : Trigger.new){
    //Make sure the lead has an email address
    if (l.Email != null){
        //Find a duplicate
        String leadEmail = l.Email;
        String leadId = l.Id;
        
        //If a duplicate is found, update the Owner field.
        if(dupeleads.size() > 0){
            dupeleads[0].OwnerId = l.OwnerId;
            dupeleads[0].Email = l.Email;
        }
    }
}

}

Answer 1

You forgot to aggregate the emails you want to query, as I demonstrate in my Aggregate-Query-Update Pattern blog post. Note also that your code was not bulkified.

Set<String> emails = new Set<String>();
Map<String, Id> ownerIds = new Map<String, Id>();
Id ownerId;
// Aggregate Values to Query
for(Lead record: Trigger.new) {
  emails.add(record.Email);
}
// Ignore null
emails.remove(null);
// Query matching records
for(Lead record: [SELECT Email, OwnerId FROM Lead WHERE Email = :emails AND Id != :Trigger.new]) {
  ownerIds.put(record.Email, record.OwnerId);
}
// Update records in trigger
for(Lead record: Trigger.new) {
  if((ownerId = ownerIds.get(record.Email)) != null) {
    record.OwnerId = ownerId;
  }
}