Updating Child records in bulk

Question

I am trying to update the children records when the parent field is updated. The code I have works but I was wondering is it the optimized for data loads. So if a user uploads 1000 Lease records and each Lease record has 20 child records. Will the code I have work well? Thanks.

declared at class level: List <Lease_Payment_Term__c > lpt = new ListLease_Payment_Term__c >();

global void bulkAfter(){
  if( Trigger.isUpdate || Trigger.isInsert){
        List <Lease_Payment_Term__c > lpt = new ListLease_Payment_Term__c >();
        List<Id> leaseIds = new List<Id>();
        for( SObject record : Trigger.new ){
            Lease__c newlease = ( Lease__c ) record;
            if( newlease.Status__c == 'Expired'){
                leaseIds.add( newlease.Id);
            }
        }

            lpt = [Select id,Status__c from Lease_Payment_Term__c 
                WHERE Status__c = 'Active' and Lease__c IN : leaseIds
            ];

            if( lpt.size() > 0){
                for(Lease_Payment_Term__c lpts : lpt){
                    lpts.status__c = 'Expired';
                }
                
                update lpt;
            } 
    }
}

Answer 1

The big things to avoid are:

• Queries inside of loops
• DML inside of loops

That right there is 95% of bulkification, and it doesn't look like that's an issue in your code.

About the only thing I could suggest here is to use a parent-child subquery to do the heavy lifting.

ex...

if( Trigger.isUpdate || Trigger.isInsert){
    List<Lease_Payment_Term__c> lptsToExpire = new List<Lease_Payment_Term__c>();

    for(Lease__c lease :[SELECT Id, (SELECT Id FROM Lease_Payment_Terms__r WHERE Status__c = 'Active') FROM Lease__c WHERE Status__c = 'Expired' AND Id IN :trigger.new]){
        for(Lease_Payment_Term__c lpt :lease.Lease_Payment_Terms__r){
            lpt.Status__c = 'Expired';
            lptsToExpire.add(lpt);
        }
    }

    update lptsToExpire;
}

I'm taking a guess at the child relationship name, and using __r in the places I did is intentional. If you don't understand what the query is doing, or what that __r business is, then going through the documentation on Relationship Queries should help.