Defining record type in Trigger

Question

I need some help, I have the following trigger, however I get the following error message “Error: Compile Error: expecting a right parentheses, found 'Integer' at line 5 column 8” What I am trying to do, is just make this trigger work for this one record type.

Record type ID = '012R00000004wJv'

My trigger is

trigger ObjectNameCheckProducts on Campaign (before insert, before update) {
  for(Campaign o : Trigger.New){

    If(o.Campaign.RecordType == '012R00000004wJv'
    Integer counter = 0;

    if(o.Institutional_Products_A_G__c != null) 
       counter += o.Institutional_Products_A_G__c.split(';').size();
    if(o.Institutional_Products_G_Z__c != null)
       counter += o.Institutional_Products_G_Z__c.split(';').size();
    if(o.Intermediary_Products_A_F__c != null)
       counter += o.Intermediary_Products_A_F__c.split(';').size();
    if(o.Intermediary_Products_G_L__c != null)
       counter += o.Intermediary_Products_G_L__c.split(';').size();
    if(o.Intermediary_Products_M_Z__c != null)
       counter += o.Intermediary_Products_M_Z__c.split(';').size();

    if(counter > 5) o.addError('Max 5 values can be selected from Product lists');
 }    

}

Answer 1

Compile Error: expecting a right parentheses, found 'Integer'

and

If(o.Campaign.RecordType == '012R00000004wJv'

Looks like your if statement is missing a right parentheses. Note that the full error message say that it found 'Integer' on the line after (line 5) the if statement - with no closing parentheses at the end of line 4, the parser kept going until it found something that didn't belong in an if statement. If you don't see the error on the line indicated, always look at the line(s) directly above.

Also, the field you need to check is RecordTypeId, not RecordType (see reference). Try this:

If(o.Campaign.RecordTypeId == '012R00000004wJv')

However, you shouldn't be hardcoding a record type id (or any id) into your code. Instead, look up the record type id by name. You could query the RecordType table, but there's a better way (reference):

trigger ObjectNameCheckProducts on Campaign (before insert, before update) {
  // Look up record type id
  String recordTypeName = 'Long-Term Strategic Products'; // <-- Change this to your record type name
  Map<String,Schema.RecordTypeInfo> rtMapByName = Schema.SObjectType.Campaign.getRecordTypeInfosByName();
  Schema.RecordTypeInfo rtInfo =  rtMapByName.get(recordTypeName);
  id recordTypeId = rtInfo.getRecordTypeId();

  for(Campaign o : Trigger.New){
    if(o.RecordTypeId == recordTypeId) {
      Integer counter = 0;

      if(o.Institutional_Products_A_G__c != null) 
        counter += o.Institutional_Products_A_G__c.split(';').size();
      if(o.Institutional_Products_G_Z__c != null)
        counter += o.Institutional_Products_G_Z__c.split(';').size();
      if(o.Intermediary_Products_A_F__c != null)
        counter += o.Intermediary_Products_A_F__c.split(';').size();
      if(o.Intermediary_Products_G_L__c != null)
        counter += o.Intermediary_Products_G_L__c.split(';').size();
      if(o.Intermediary_Products_M_Z__c != null)
        counter += o.Intermediary_Products_M_Z__c.split(';').size();

      if(counter > 5) o.addError('Max 5 values can be selected from Product lists');
    }
  }
}    

Finally - Note the added braces after the initial if, wrapping the other if statements.

Answer 2

It looks like you're trying to implement this Maximum 5 check for the given record type. If so, you'll need to encompass all the counter increment logic in the if statement (see my edit below).

Furthermore, hardcoding Ids is a terrible idea and worst practice. Either switch the RecordType check to use a Custom Setting instead, or use an additional query to fetch the Record Type Id before looping over the trigger results.

More on custom settings here: https://www.salesforce.com/us/developer/docs/apexcode/Content/apex_methods_system_custom_settings.htm

trigger ObjectNameCheckProducts on Campaign (before insert, before update) {
    for(Campaign o : Trigger.New){

    //Assuming you have created a custom hierarchy setting with CampaignRecordType__c field
        if(o.Campaign.RecordType ==  Custom_Setting__c.getInstance().CampaignRecordType__c){ 
            Integer counter = 0;

            if(o.Institutional_Products_A_G__c != null) 
                counter += o.Institutional_Products_A_G__c.split(';').size();
            if(o.Institutional_Products_G_Z__c != null)
                counter += o.Institutional_Products_G_Z__c.split(';').size();
            if(o.Intermediary_Products_A_F__c != null)
                counter += o.Intermediary_Products_A_F__c.split(';').size();
            if(o.Intermediary_Products_G_L__c != null)
                counter += o.Intermediary_Products_G_L__c.split(';').size();
            if(o.Intermediary_Products_M_Z__c != null)
                counter += o.Intermediary_Products_M_Z__c.split(';').size();

            if(counter > 5) o.addError('Max 5 values can be selected from Product lists');
        }
    }    
}

Alternatively, here is what you could do instead, with querying for recordtype.developername:

trigger ObjectNameCheckProducts on Campaign (before insert, before update) {

    Id recordTypeId = [Select Id From RecordType Where SObjectType = 'Campaign' And DeveloperName='Your RT's dev name'].Id;

    for(Campaign o : Trigger.New){
        if(o.Campaign.RecordType == recordTypeId){ 
            Integer counter = 0;

            if(o.Institutional_Products_A_G__c != null) 
                counter += o.Institutional_Products_A_G__c.split(';').size();
            if(o.Institutional_Products_G_Z__c != null)
                counter += o.Institutional_Products_G_Z__c.split(';').size();
            if(o.Intermediary_Products_A_F__c != null)
                counter += o.Intermediary_Products_A_F__c.split(';').size();
            if(o.Intermediary_Products_G_L__c != null)
                counter += o.Intermediary_Products_G_L__c.split(';').size();
            if(o.Intermediary_Products_M_Z__c != null)
                counter += o.Intermediary_Products_M_Z__c.split(';').size();

            if(counter > 5) o.addError('Max 5 values can be selected from Product lists');
        }
    }    
}