Mass upsert Master Detail records at the same time

Question

I have two custom objects with Master Detail relationship. I need to be able to bulk upsert these records simultaneously. For example:

If the master records don't exist, create them. Otherwise, create them. If detail records don't exist for these master records, create them. Otherwise, update them.

The master object has only two fields: One text field and one checkbox. The detail object has only one additional field that is a checkbox.

In other words, master records and their related detail records may or may not exist. I need to be able to create either single master records or multiple master records (along with their detail records).

I tried to do some research and found this.

This solution is using an external field and that seems to be the right way to go. However, I don't understand how to bulkify the code.

Any help you can provide is appreciated. Let me know if you need more information.

Thank you.

Answer 1

There are many ways to meet the requirement, the one below is "query-free", let me know if you cannot do as below and I would post the version with queries

A simplified version (without error control, nor partial commits, nor duplicate records, etc.) would be

In Master Record, (WaitList__c for this example)

• set the Product Number as Unique External Id (ProductNumber__c)

In second master, (Customer__c for this example)

• set the Customer Number as Unique External Id (CustomerNumber__c)

In Detail Record, (WaitListCustomer__c for this example)

• create field (ExternalId__c for this example) that is unique External id and would be the representation of the junction between customer and product. this will contain the {customer}-{product}

In your code, lets assume you receive a List<Wrapper> where wrapper is

class Wrapper {
    String Product;
    String Customer; 
} 

Then in your controller you could do

Set<WaitList__c> waitListToUpsert = new Set<WaitList__c>();
Set<WaitListCustomer__c> waitListCustomerToUpsert = new Set<WaitListCustomer__c>();

for (Wrapper forW : yourWrapperList) {
    waitListToUpsert.add(
        new WaitList__c(
            ProductNumber__c = forW.Product, 
            Waitlisted__c = true
        )
    );
    waitListCustomerToUpsert.add(
        new WaitListCustomer__c(
            WaitListLookUp__r = new WaitList__c(
                ProductNumber__c = forW.Product
            ),
            CustomerLookUp__r = new Customer__c(
                CustomerNumber__c = forW.Customer
            ),
            Waitlisted__c = true,
            ExternalId__c = forW.Customer + '-' + forW.Product
        )
    )     
} 
upsert new List<WaitList__c>(waitListToUpsert) ProductNumber__c;
upsert new List<WaitListCustomer__c>(waitListCustomerToUpsert) ExternalId__c;

You might need a trigger (if you can create this records elsewhere) / validation rule (if they are only creatable by your component) to make sure that ExternalId__c is always kept properly