Fetching the landing page details

Question

I'm fetching Job ID, Subscriber key of a subscriber into a Data Extension who clicks the landing page.

Code in the Email

%%[ SET @Sub = _subscriberkey SET @CloudPageID = 1234]%% 

Code in landing page

%%[ 

set @Subs = AttributeValue('_SubscriberKey')
 set @JobId = AttributeValue('jobID')
 set @memberid = AttributeValue("memberid")
 set @member_busname = AttributeValue('member_busname')

 Set @lookUp = LookupRows('Page Visits','Subscriber Key', @Subs,'jobid', @jobid)
 SET @lookupvalue = LookupRows('BU Details','memberid', @memberid)

IF Rowcount(@lookupvalue) >0 THEN
   SET @BURow = Row(@lookupvalue, 1)
   Set @BUName = Field(@BURow, 'BUName')
ENDIF 


 IF RowCount(@lookUp) == 0 THEN 
 InsertData('Page Visits','Subscriber Key', @Subs,'jobid', @jobid,'memberid', @memberid, 'member_busname', @member_busname , 'Event Date', NOW())
ENDIF 
 ]%%  

I've created one DE called "Landing page" and fetching the LPNAME field and inserting into Page Visits DE. I'm using the below which is not working

SET @lookupvalue = LookupRows('landing page','LPNAME', @LPNAME)

IF Rowcount(@lookupvalue) >0 THEN    SET @LPRow = Row(@lookupvalue, 1)    Set @LPName = Field(@LPRow, 'LPName') ENDIF

Thanks In advance, Kiran

Answer 1

I reviewed this with @kiran on a webinar.

He is now storing the Page URL of the CloudPage in a 'Landing Page Details' DE with the page name.

You can use this URL value to lookup the page name from the DE. In order to do this, you need to strip the query string parameters from the PAGEURL which I have done by locating the ? position using AMPscript IndexOf function and then use the Substring function to retrieve the URL, which can then be used in a lookup.

The following code will work.

%%[ 

set @Subs = AttributeValue('_SubscriberKey')
set @JobId = AttributeValue('jobID')
set @memberid = AttributeValue('memberid')
set @pageURL = RequestParameter('PAGEURL')

set @queryStringPosition = Subtract(IndexOf(@pageURL,'?'),1)

set @baseURL = Substring(@pageURL, 1, @queryStringPosition)

set @cpName = Lookup('Landing Page Details', 'CPNAME', 'pageURL', @baseURL)

SET @buName = Lookup('BU Details', 'BUName', 'memberid', @memberid)

set @pageVisits = LookupRows('Page Visits','Subscriber Key', @subs, 'pageURL', @pageURL)

if RowCount(@pageVisits)==0 then
   InsertData('Page Visits',
              'Subscriber Key', @Subs,
              'jobid', @jobid,
              'memberid', @memberid,
              'BUName', @BUName,
              'pageURL', @pageURL,
              'CPNAME', @CPNAME,
              'Event Date', NOW()
              )
endif
]%%

Answer 2

This is unfortunately not possible, as there is no personalization string holding the value of the cloud page name. My best suggestion will be either pass it in CloudPagesURL, from an ampscript variable - or to use link alias instead:

<a href="https://www.salesforce.com" alias="Make This Unique">SFMC</a>

You will be able to pass it on in your Ampscript call, like this:

InsertData('Page Visits','Subscriber Key', @Subs,'jobid', @jobid,'memberid', @memberid, 'member_busname', @member_busname , 'linkname', linkname, 'Event Date', NOW())

Be aware, that you don't need to pass these standard personalisation strings as Attribute Values - they are immediately available as linkname above, when you use CloudPagesURL

Answer 3

You can't get the actual landing page name, but you can retrieve the page URL along with any URL parameters using the personalization string PAGEURL. For example, set the following variable on your landing page:

set @pageURL = RequestParameter("PAGEURL")