SSJS and AMPscript

Question

I'm trying to output message if there is an error and i have very little knowledge in javascript in general.

Could I get some feedback on if the following would work or how I would go about :

• If empty parameters, output "Sorry, there was an error"
• If there is an error, output "Sorry, there was an error"

Thank you in advance!

<script runat="server">

Platform.Load("core","1.1.5");

try {
</script>
%%[

/* Retrieve Parameters */
SET @subscriberkey = _subscriberkey
SET @jobid = jobID
SET @firstname = RequestParameter("FirstName")
SET @email = RequrestParameter("Email")

/* Handle Empty Parameters */
IF EMPTY(@subscriberkey) OR EMPTY(@jobid) OR EMPTY(@firstname) OR EMPTY(@email) OR @subscriberkey =='' OR @jobid == '' OR @listid == '' OR @Email == ''THEN
  SET @message = "Sorry, there was an error."
ENDIF

/*Lookup DE and Update if doesn't exist */
SET @Rows = LookupRows('DEName', "SubscriberKey", @subscriberkey)

IF RowCount(Rows) > 0 THEN 
   SET @message = "You've already registered."
ELSE
   SET InsertDE = InsertData('DEName','SubscriberKey', @subscriberkey, 'Email',@Email)
   SET @message = "Thanks for registering"
ENDIF

]%%

%%=v(@message)=%%

<script runat="server">
} catch (e) {
  Write("<br>" + Stringify(e))
}

</script>

Answer 1

Here are a couple changes (based on comments by @Abhishek and @LukasLunow) as well as a few other things I noticed. This should get you there:

<script runat="server">

Platform.Load("core","1.1.5"); // Not necessary if just doing try/catch. Unnecessary processing

try {
</script>
%%[

/* Retrieve Parameters */
SET @subscriberkey = AttributeValue("_subscriberkey") /* Set to AttributeValue for null handling */
SET @jobid = AttributeValue("jobID") /* Set to AttributeValue for null handling */
SET @firstname = RequestParameter("FirstName")
SET @email = RequestParameter("Email") /*Spelling mistake on function. changed from RequrestParameter to RequestParameter */

/* Handle Empty Parameters */
IF EMPTY(@subscriberkey) OR EMPTY(@jobid) OR EMPTY(@firstname) OR EMPTY(@email) THEN /* Removed unncessary conditions */
  SET @message = "Sorry, there was an error."
ENDIF

/*Lookup DE and Update if doesn't exist */
SET @Rows = LookupRows('DEName', "SubscriberKey", @subscriberkey)

IF RowCount(@Rows) > 0 THEN   /* Added @ to AMPscript Variable Rows */
   SET @message = "You've already registered."
ELSE
   SET @InsertDE = InsertData('DEName','SubscriberKey', @subscriberkey, 'Email', @Email) /* Added @ to AMPScript Var InsertDE */
   SET @message = "Thanks for registering"
ENDIF

]%%

%%=v(@message)=%%

<script runat="server">
} catch (e) {
  //Write("<br>" + Stringify(e)) //This will display the error code/description if it fails, not your custom message
  Write("Sorry, there was an error.") //This will display your custom message if it fails
}

</script>

List of recommended changes:

1. Remove Core Library call (if you are just using SSJS for try/catch)
2. Utilize AttributeValue() on personalization strings for null handling (mostly just personal preference, not really necessary)
3. Spelling mistake on RequestParameter function when setting @email
4. Remove unnecessary conditions for Empty Parameters IF statement
5. Added @ to AMPscript var 'Rows'
6. Added @ to AMPscript var 'InsertDE'
7. Provided SSJS Write function with your custom message instead of the error details inside of catch