Add Async Triggers into a Managed Package

Question

Salesforce released the Process Change Event Messages in Apex Triggers in Summer '19, is this feature available in the managed package?

Answer 1

Yes this feature is available for managed package .

In order to test this i created a simple package with the below code

Trigger code

---

trigger AccountChangeAsyncTrigger on AccountChangeEvent (after insert) {
List<AccountChangeEvent> changes = Trigger.new;

Set<String> accIds = new Set<String>();
List<Contact> lstcontacts = new List<Contact>();

//Get all record Ids for this change and add it to a set for further processing
for(AccountChangeEvent acc: changes){
    List<String> recordIds = acc.ChangeEventHeader.getRecordIds();
    accIds.addAll(recordIds);
}

for(Id accId: accIds) {
    Contact c = new Contact();
    c.LastName = 'Test';
    c.AccountId = accId;
    lstcontacts.add(c);
}

   insert lstcontacts;
}

---

Test Code

---

@isTest
public class TestAccountChangeAsyncTrigger {
@isTest
static  void testAsyncContactCreate() { 
    // Enable all Change Data Capture entities for notifications.
    Test.enableChangeDataCapture();

    Test.startTest();
    // Insert an account to generate a change event.
    insert new Account(Name='TestAccount', Phone='4155551212');
    Test.stopTest();
    // The stopTest() call fires the trigger with the test account change event.

    // VERIFICATIONS
    // Check that the change event trigger created a task.
    Contact[] contactList = [SELECT Id FROM Contact];        
    System.assertEquals(1, contactList.size(),
        'The change event trigger did not create the expected contact.');
   }
}

Created a managed package and installed the package in another environment and everything worked as expected .

NOTE: You will need to enable change data capture for the object on which you want this feature .

For custom objects include the custom object in the package that will also include the async trigger as a part of dependency .

FYI

---

In case you are following the comments there is alternate way to write tests for this

@isTest
public class TestAccountChangeAsyncTrigger {
@isTest
static  void testAsyncContactCreate() { 

    Test.startTest();

    // Insert an account to generate a change event.
    insert new Account(Name='TestAccount', Phone='4155551212');
    // Enable all Change Data Capture entities for notifications.
    Test.getEventBus().deliver();

    Test.stopTest();
    // The stopTest() call fires the trigger with the test account change event.

    // VERIFICATIONS
    // Check that the change event trigger created a task.
    Contact[] contactList = [SELECT Id FROM Contact];        
    System.assertEquals(1, contactList.size(),
        'The change event trigger did not create the expected contact.');
  }
}