Pass a list attribute lightning to apex controller

Question

I have an attribute in lightning component and it has a value like this:

<aura:attribute name="samListObj" type="Object"/>

[{"created":"","description":"","docId":"","docType":"Claims Documents","docTypeList":[],"fileName":""}, 
{"created":"","description":"","docId":"","docType":"Client Identification Documents","docTypeList":[],"fileName":""}, 
{"created":"","description":"","docId":"","docType":"Execution Only","docTypeList":[],"fileName":""}, 
{"created":"","description":"","docId":"","docType":"Invoice","docTypeList":[],"fileName":""},
{"created":"","description":"","docId":"","docType":"Ongoing Advice Agreements","docTypeList":[],"fileName":""}]

Now I am passing the value into my Apex Class Controller from my lightning controller, like this:

var action = component.get('c.controllerMethod');
action.setParams({
 'samValue':component.get('v.samListObj')
});
action.setCallBack(this,function(result){
  if(result.getState()){
   console.log('SUCCESS');
  }
});
$A.enqueueAction(action);

Now in Apex code I have a wrapper class with the same field from my attribute like this:

public class DocumentWrapper {
    @AuraEnabled 
    public String docId = ''; 
    @AuraEnabled 
    public String docType = ''; 
    @AuraEnabled 
    public String fileName = '';
    @AuraEnabled 
    public String created = '';  
    @AuraEnabled 
    public String description = '';   
    @AuraEnabled 
    public List<String> docTypeList = new List<String>();      
}

So for my method that calls to my lightning js controller:

@AuraEnabled
public static void updateAPDesciptionCFCheck(List<DocumentWrapper> samValue){
   System.debug(samValue);
}

Now I tried to debug the value from my lightning component but it returns empty in every fields:

DocumentWrapper:[created=, description=, docId=, docType=, docTypeList=(), fileName=], 
DocumentWrapper:[created=, description=, docId=, docType=, docTypeList=(), fileName=], 
DocumentWrapper:[created=, description=, docId=, docType=, docTypeList=(), fileName=], 
DocumentWrapper:[created=, description=, docId=, docType=, docTypeList=(), fileName=], 
DocumentWrapper:[created=, description=, docId=, docType=, docTypeList=(), fileName=]

For the docType field it should have a value base from the value of the attribute in my component. But I couldn't pull the data.

Any help please?

NOTE: I updated the actual display in my debug log.

Answer 1

Did some quick testing, and there are 2 options to resolve the issue:

1. Irrespective of whether your wrapper class is outer or inner, add {get; set;} to @AuraEnabled properties for data binding to work.

   public class DocumentWrapper {
       @AuraEnabled 
       public String docId { get; set; } 
       @AuraEnabled 
       public String docType { get; set; }
       @AuraEnabled 
       public String fileName { get; set; }
       @AuraEnabled 
       public String created { get; set; }
       @AuraEnabled 
       public String description { get; set; }
       @AuraEnabled 
       public List<String> docTypeList { get; set; }     
   }
   

   Quoting from documentation- Passing Data to an Apex Controller:

   Each property in the Apex class must have an @AuraEnabled annotation, as well as a getter and setter.

2. Another safer option which I prefer to use is to send a serialized JSON string to server side and deserialize that in apex method.

   From client side controller, you can serialize the attribute to string with JSON.stringify:

   action.setParams({ 'samValue' : JSON.stringify(component.get('v.samListObj')) });
   

   Then in apex controller method, deserialize it as:

   public with sharing class Class_267042 {
       @AuraEnabled
       public static void updateAPDesciptionCFCheck(String samValueString){
           List<DocumentWrapper> samValue = (List<DocumentWrapper>) JSON.deserialize(samValueString, List<DocumentWrapper>.class);
       }
   }