casting a map of Id, SObject to a map of Id, customObject

Question

Map<Id, Segment__c> noLockedRecordsMap = 
    (Map<Id, Segment__c>)new LockedRecordHandler().removeLockedRecords(newMap);

The above compiles fine. Get this error at runtime:

Invalid conversion from runtime type Map to Map Class

Here's the method it's calling:

public Map<Id, SObject> removeLockedRecords(Map<Id, SObject> newMap) {
     Map<Id, SObject> returnMap = new Map<Id, SObject>();
     for (SObject s : newMap.values()) {
         if (!(Boolean)s.get('Locked__c')) {
             returnMap.put((Id)s.get('Id'), s);
        }
     }
     return returnMap;
}

Anyone have experience with this?

Answer 1

If you open up the details of the error message, it probably says Invalid conversion from runtime type Map<Id, SObject> to Map<Id, Segment__c> Class. You can't convert Maps with a different type specialization, even if the changed types are convertible. In the particular case of converting a Map<Id, sObject> to a Map<Id, Specific_SObject__c> where the key is the Id of the sObject value, you could do this by taking advantage of the List constructor for Map:

Map<Id, Segment__c> noLockedRecordsMap = new Map<Id, Segment__c>(
           (List<Segment__c>)new LockedRecordHandler().removeLockedRecords(newMap).values()
       );

In all other cases, you should loop through the map and put its key-value pairs in a new map:

Map<Id, Segment__c> noLockedRecordsMap = new Map<Id, Segment__c>();
Map<Id, SObject> lockedRecordsSObject = new LockedRecordHandler().removeLockedRecords(newMap);
for(Id key : lockedRecordsSObject.keySet())
{
    noLockedRecordsMap.put(key, (Segment__c)lockedRecordsSObject.get(key));
}

This could probably also be done by doing round-trip JSON, but the only advantage to that is saving lines of code, most likely it won't be faster. Hopefully in the future Apex will support methods with generic arguments so that it can return a map of the correct type and this won't be necessary.

Answer 2

You should not try to put a generic type in to a concrete type. This can cause bugs. The ideal situation is to create a copy so you retain the concrete type:

public Map<Id, SObject> removeLockedRecords(Map<Id, SObject> newMap) {
     // Make a copy //
     Map<Id, SObject> returnMap = newMap.clone();
     // Clear out existing key/values in copy (not original) //
     returnMap.clear();
     for (SObject s : newMap.values()) {
         if (!(Boolean)s.get('Locked__c')) {
             returnMap.put((Id)s.get('Id'), s);
        }
     }
     return returnMap;
}

By using clone, you preserve the original type that was passed in, and then your cast won't fail in the end.

Answer 3

Just change your signature to accept List<SObject> instead. You are only using the Map.values() result anyway.

public Map<Id, SObject> myMethod(List<SObject> records)
{
    Map<Id, SObject> unlocked = new Map<Id, SObject>();
    for (SObject record : records)
    {
        // same logic here
    }
    return unlocked;
}