Sending Messages with Dynamic Content

Question

I'm starting with AMPscript, and I need to send a batch of email messages to my customers where each one receives a slightly different content, which should be obtained dynamically for each email

To clarify, it's not a random value, is something I'll know in advance and is a value that needs to be unique between customers.

To simplify, let's say that the first email I sent to the first customer in my batch has this text (the number is just an example, the real value is non-numeric, non-sequential and I know it in advance):

Hello, customer #1 !

The second email in the batch, should look like this:

Hello, customer #2 !

And so on, where each email should have a different unique value (#3, #4, ...) Is this possible with AMPscript? Where should I put the dynamic information? (In my example, that would be the values 1, 2, 3, 4, ...) I'm a bit confused with the documentation, because they clearly state that:

When writing your AMPscript, always remember that all calls will process at the end of the subscriber batch when performing email sends

And I interpret the above as "the script is executed exactly once" at the end of a batch of messages, making it impossible to implement my use case. Is my interpretation correct?

Answer 1

It almost sounds like you need a “voucher solution”, where ClaimRow is your friend.

You need to build a Data Extension with few columns, as described in the documentation, one of them being populated with the values you want to send out to your recipients. In the email, you need to put code similar to this below, taking one of the values and assigning to a recipient. Hence you can later look up, what value was sent to who.

%%[VAR @CouponRow
SET @CouponRow = ClaimRow('Coupon', 'IsClaimed', 'JobID', JobID, 'ListID', ListID, 'BatchID', _JobSubscriberBatchID, 'SubscriberID', SubscriberID)
IF EMPTY(@CouponRow) THEN ]%%
No coupons available
%%[ ELSE ]%%
Your Coupon Code is %%=FIELD(@CouponRow,'CouponCode') =%%
%%[ ENDIF ]%%

Some additional help can be found here:

https://sprignaturemoves.com/coupon-claiming-in-ampscript/

Send a coupon - Claim row

Unique coupon codes to same subscriber

Answer 2

As @JohannesSchapdick stated, the AMPScript is run once per subscriber and is executed right before being pushed into the send queue. This means you cannot pass a value from one subscriber to the next directly.

To be able to implement something that includes an ordinal numbering system, you have a couple options:

You first can just upload the values into your sendable DE and reference them there if they are pre-existing.

Option 1: (preferred if you do not have pre-assigned values.)

1. Create a new field inside your DE named 'UniqueCode'
2. Create a SQL query to fill this row in via SQL's NewID() function
3. Inside your email, you reference the corresponding field using AttributeValue()

For example:

SQL (very basic sample)

SELECT yourPKEY
NewID() AS UniqueCode
FROM [your DE]
/*Target: [your DE] */
/*Action: update */

AMPscript and output:

%%[
   set @UniqueCode = AttributeValue("UniqueCode")
]%%

%%=v(@UniqueCode)=%%

Option 2 (If you need a unique value, but do not want to assign until send time)

You need to include the new field inside your DE, similar to Option1. Use the AMPscript GUID() function to fill in a random value. You then upsert this value to the DE for future reference.

e.g.

%%[
    SET @GUID = GUID()
    UPSERTDATA("yourDE", 1, "yourPkey", yourPkey, "UniqueCode", @GUID)
]%%

Option 3: (Best if you have pre-assigned codes and do not want to include in your sendable DE)

In this option you would use a separate DE with 2 columns and 1 row. You then would do Lookups and Upserts to manipulate this DE.

1. Create a DE with the following rows PrimaryKey | UniqueCode. You would add in each PKey from your original DE.
2. Upload your list of unique codes assigned to your Pkeys.
3. Push in AMPscript to lookup this value

Example AMPScript:

In beginning of email (before number needs to be used)

%%[ 
    SET @uniqueCode = Lookup("yourLookupDE", "UniqueCode", "Pkey", yourPkey)
]%%

---

EDITED

I edited my answer to include options of codes outside of ordinal.

Answer 3

You need to know which kind of rules are the reason that your customers receive different content.

You could just create a dynamic content block with these rules to achieve it or create ampscript codeblocks / content blocks.

When writing your AMPscript, always remember that all calls will process at the end of the subscriber batch when performing email sends.

The above statement means that the ampscript will be executed when the email is inside the sending process (gets executed just before the email send process itself) on the server which then populates the content.

The script is therefore executed for each subscriber once (not once for all).

%%[
var @var
set @var = [dataextensioncolumnname]
IF @var = "something" THEN

]%%
Text number 1
%%[
ELSE 
]%%
Text number 2
%%[
ENDIF
]%%

or better ampscript that just uses variables that get populated differently. And then print out the variables at the end with commands like %%=v(@var)=%%