Dynamic Apex Class

Question

I am using Tooling API to create a class. Used the following link as reference to create a class and it works fine. But if i try to make it bit more dynamic by putting Apex Class Name in string and using it in the Body it doesn't work. I am getting following Error : "unexpected token: 'MyNewClass'","errorCode":"INVALID_FIELD_FOR_INSERT_UPDATE".

**EDIT

Following is the code snippet which i ran from the developer console.

String salesforceHost = System.Url.getSalesforceBaseURL().toExternalForm();

String url =  salesforceHost + '/services/data/v28.0/tooling/sobjects/ApexClass';

String sampleClass = 'MyNewClass';

String classBody = 'public class ' + sampleClass + ' {\\n' 
        + ' public ' + sampleClass + ' {\\n'
        + '\\n' 
        + ' }\\n'
        + '}';


HttpRequest req = new HttpRequest();

req.setMethod('POST');
req.setEndpoint(url);
req.setHeader('Content-type', 'application/json');
req.setHeader('Authorization', 'OAuth ' + UserInfo.getSessionId());        
req.setBody('{'+
    '"Body" : "' + classBody +'"'+
 '}');
Http http = new Http();
HTTPResponse res = http.send(req);
String resBody = res.getBody();

Note : if i change the first two lines of classBody it will work i.e.

String classBody = 'public class MyNewClass {\\n' 
        + ' public MyNewClass {\\n'

Did i miss anything?

UPDATE

Use Double Back Slash by default since it works all the time. if you want to format the body contents by providing space then single slash may not work at times.

Thanks

Answer 1

I found two problems with your dynamically constructed Apex code which I have addressed below.

• You only need one back slash to inject the carriage return character into the code
• You had not declared the class constructor correctly, it needed the braces ()

After i made these changes and applied to my Apex Tooling API code below it worked.

// Create the ApexClass via Tooling REST API
String sampleClass = 'MyNewClass';
String classBody = 'public class ' + sampleClass + ' {\n' 
        + ' public ' + sampleClass + '() {\n'
        + '\n' 
        + ' }\n'
        + '}';
JSONGenerator body = JSON.createGenerator(false);
body.writeStartObject();
body.writeStringField('Name', sampleClass);
body.writeStringField('Body', classBody);
body.writeEndObject();
HttpRequest createReq = new HttpRequest();
createReq.setEndpoint(URL.getSalesforceBaseUrl().toExternalForm() + '/services/data/v29.0/tooling/sobjects/ApexClass');
createReq.setBody( body.getAsString() );
createReq.setHeader('Authorization', 'OAuth ' + UserInfo.getSessionId());
createReq.setHeader('Content-Type', 'application/json');
createReq.setMethod('POST');
Http h = new Http();    
HttpResponse createRes = h.send(createReq);